app-emulation/crossover-bin/crossover-bin-17.5.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 PYTHON_COMPAT=( python2_7 )
   6 PYTHON_REQ_USE="threads"
   7
   8 inherit python-single-r1 unpacker
   9
  10 DESCRIPTION="Commercial version of app-emulation/wine with paid support."
  11 HOMEPAGE="https://www.codeweavers.com/products/"
  12 SRC_URI="https://media.codeweavers.com/pub/crossover/cxlinux/demo/install-crossover-${PV}.bin"
  13
  14 LICENSE="CROSSOVER-3"
  15 SLOT="0"
  16 KEYWORDS="-* ~amd64 ~x86"
  17 IUSE="+capi +cups doc +gphoto2 +gsm +jpeg +lcms +ldap +mp3 +nls +openal +opencl +opengl +png +scanner +ssl +v4l"
  18 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  19 RESTRICT="bindist test"
  20 QA_FLAGS_IGNORED="opt/cxoffice/.*"
  21 QA_PRESTRIPPED="opt/cxoffice/lib/.*
  22         opt/cxoffice/bin/cxburner
  23         opt/cxoffice/bin/cxntlm_auth
  24         opt/cxoffice/bin/wineserver
  25         opt/cxoffice/bin/unrar
  26         opt/cxoffice/bin/wine-preloader
  27         opt/cxoffice/bin/cxdiag
  28         opt/cxoffice/bin/cxgettext
  29         opt/cxoffice/bin/wineloader
  30         "
  31 S="${WORKDIR}"
  32
  33 DEPEND="dev-lang/perl
  34         app-arch/unzip
  35         ${PYTHON_DEPS}"
  36
  37 RDEPEND="${DEPEND}
  38         !prefix? ( sys-libs/glibc )
  39         $(python_gen_cond_dep '
  40                 >=dev-python/pygtk-2.10[${PYTHON_MULTI_USEDEP}]
  41                 dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
  42         ')
  43         dev-util/desktop-file-utils
  44         !app-emulation/crossover-office-pro-bin
  45         !app-emulation/crossover-office-bin
  46         capi? ( net-libs/libcapi[abi_x86_32(-)] )
  47         cups? ( net-print/cups[abi_x86_32(-)] )
  48         gsm? ( media-sound/gsm[abi_x86_32(-)] )
  49         jpeg? ( virtual/jpeg[abi_x86_32(-)] )
  50         lcms? ( media-libs/lcms:2 )
  51         ldap? ( net-nds/openldap[abi_x86_32(-)] )
  52         gphoto2? ( media-libs/libgphoto2[abi_x86_32(-)] )
  53         mp3? ( >=media-sound/mpg123-1.5.0[abi_x86_32(-)] )
  54         nls? ( sys-devel/gettext[abi_x86_32(-)] )
  55         openal? ( media-libs/openal[abi_x86_32(-)] )
  56         opencl? ( virtual/opencl[abi_x86_32(-)] )
  57         opengl? (
  58                 virtual/glu[abi_x86_32(-)]
  59                 virtual/opengl[abi_x86_32(-)]
  60         )
  61         png? ( media-libs/libpng:0[abi_x86_32(-)] )
  62         scanner? ( media-gfx/sane-backends[abi_x86_32(-)] )
  63         ssl? ( dev-libs/openssl:0[abi_x86_32(-)] )
  64         v4l? ( media-libs/libv4l[abi_x86_32(-)] )
  65         media-libs/alsa-lib[abi_x86_32(-)]
  66         >=media-libs/freetype-2.0.0[abi_x86_32(-)]
  67         media-libs/mesa[abi_x86_32(-)]
  68         sys-apps/util-linux[abi_x86_32(-)]
  69         sys-libs/ncurses-compat:5[abi_x86_32(-)]
  70         sys-libs/zlib[abi_x86_32(-)]
  71         x11-libs/libICE[abi_x86_32(-)]
  72         x11-libs/libSM[abi_x86_32(-)]
  73         x11-libs/libX11[abi_x86_32(-)]
  74         x11-libs/libXau[abi_x86_32(-)]
  75         x11-libs/libXdmcp[abi_x86_32(-)]
  76         x11-libs/libXext[abi_x86_32(-)]
  77         x11-libs/libXi[abi_x86_32(-)]
  78         x11-libs/libXrandr[abi_x86_32(-)]
  79         x11-libs/libXxf86vm[abi_x86_32(-)]
  80         x11-libs/libxcb[abi_x86_32(-)]"
  81
  82 pkg_nofetch() {
  83         einfo "Please visit ${HOMEPAGE}"
  84         einfo "and place ${A} into your DISTDIR directory"
  85 }
  86
  87 src_unpack() {
  88         # self unpacking zip archive; unzip warns about the exe stuff
  89         unpack_zip ${A}
  90 }
  91
  92 src_prepare() {
  93         python_fix_shebang .
  94
  95         sed -i \
  96                 -e "s:xdg_install_icons(:&\"${ED}\".:" \
  97                 -e "s:\"\(.*\)/applications:\"${ED}\1/applications:" \
  98                 -e "s:\"\(.*\)/desktop-directories:\"${ED}\1/desktop-directories:" \
  99                 "${S}/lib/perl/CXMenuXDG.pm"
 100
 101         # Remove unnecessary files
 102         rm -r license.txt guis/ || die "Could not remove files"
 103         use doc || rm -r doc/ || die "Could not remove files"
 104 }
 105
 106 src_install() {
 107         # Install crossover symlink, bug #476314
 108         dosym ../cxoffice/bin/crossover /opt/bin/crossover
 109
 110         # Install documentation
 111         dodoc README changelog.txt
 112         rm README changelog.txt || die "Could not remove README and changelog.txt"
 113
 114         # Install files
 115         dodir /opt/cxoffice
 116         #cp -r ./* "${ED}opt/cxoffice" \
 117         find . | cpio -dumpl "${ED}/opt/cxoffice" 2>/dev/null \
 118                 || die "Could not install into ${ED}opt/cxoffice"
 119
 120         # Install configuration file
 121         insinto /opt/cxoffice/etc
 122         doins share/crossover/data/cxoffice.conf
 123
 124         # Install menus
 125         # XXX: locate_gui.sh automatically detects *-application-merged directories
 126         # This means what we install will vary depending on the contents of
 127         # /etc/xdg, which is a QA violation. It is not clear how to resolve this.
 128         XDG_DATA_HOME="/usr/share" XDG_CONFIG_HOME="/etc/xdg" \
 129                 "${ED}opt/cxoffice/bin/cxmenu" --destdir="${ED}" --crossover --install \
 130                 || die "Could not install menus"
 131
 132         rm "${ED}usr/share/applications/"*"Uninstall CrossOver Linux.desktop" \
 133                 || die "Could not remove uninstall menus"
 134         sed -i \
 135                 -e "s:\"${ED}\".::" \
 136                 -e "s:${ED}::" \
 137                 "${ED}/opt/cxoffice/lib/perl/CXMenuXDG.pm" \
 138                 || die "Could not fix paths in ${ED}/opt/cxoffice/lib/perl/CXMenuXDG.pm"
 139         sed -i -e "s:${ED}:/:" \
 140                 "${ED}usr/share/applications/"*"CrossOver.desktop" \
 141                 || die "Could not fix paths of *.desktop files"
 142 }
 143
 144 pkg_postinst() {
 145         einfo "${P} is open source software with the exception of the GUI."
 146         einfo "Source code can be obtained from:"
 147         einfo
 148         einfo "https://media.codeweavers.com/pub/crossover/source/crossover-sources-${PV}.tar.gz"
 149 }