app-emulation/crossover-bin/crossover-bin-13.2.0-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 PYTHON_COMPAT=( python2_7 )
   6 PYTHON_REQ_USE="threads"
   7
   8 inherit python-single-r1 unpacker
   9
  10 DESCRIPTION="Commercial version of app-emulation/wine with paid support."
  11 HOMEPAGE="http://www.codeweavers.com/products/crossover/"
  12 SRC_URI="install-crossover-${PV}.bin"
  13
  14 LICENSE="CROSSOVER-2"
  15 SLOT="0"
  16 KEYWORDS="-* ~amd64 ~x86"
  17 IUSE="+capi +cups doc +gphoto2 +gsm +jpeg +lcms +ldap +mp3 +nls +openal +opengl +png +scanner +ssl +v4l"
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19 RESTRICT="bindist fetch test"
  20
  21 QA_FLAGS_IGNORED="opt/cxoffice/.*"
  22 QA_PRESTRIPPED="opt/cxoffice/lib/.*
  23         opt/cxoffice/bin/cxburner
  24         opt/cxoffice/bin/cxntlm_auth
  25         opt/cxoffice/bin/wineserver
  26         opt/cxoffice/bin/unrar
  27         opt/cxoffice/bin/wine-preloader
  28         opt/cxoffice/bin/cxdiag
  29         opt/cxoffice/bin/cxgettext
  30         opt/cxoffice/bin/wineloader
  31         "
  32 S="${WORKDIR}"
  33
  34 DEPEND="dev-lang/perl
  35         app-arch/unzip
  36         ${PYTHON_DEPS}"
  37
  38 RDEPEND="${DEPEND}
  39         !prefix? ( sys-libs/glibc )
  40         >=dev-python/pygtk-2.10[${PYTHON_USEDEP}]
  41         dev-python/dbus-python[${PYTHON_USEDEP}]
  42         dev-util/desktop-file-utils
  43         !app-emulation/crossover-office-pro-bin
  44         !app-emulation/crossover-office-bin
  45         capi? ( net-libs/libcapi[abi_x86_32(-)] )
  46         cups? ( net-print/cups[abi_x86_32(-)] )
  47         gsm? ( media-sound/gsm[abi_x86_32(-)] )
  48         jpeg? ( virtual/jpeg[abi_x86_32(-)] )
  49         lcms? ( media-libs/lcms:2 )
  50         ldap? ( net-nds/openldap[abi_x86_32(-)] )
  51         gphoto2? ( media-libs/libgphoto2[abi_x86_32(-)] )
  52         mp3? ( >=media-sound/mpg123-1.5.0[abi_x86_32(-)] )
  53         nls? ( sys-devel/gettext[abi_x86_32(-)] )
  54         openal? ( media-libs/openal[abi_x86_32(-)] )
  55         opengl? (
  56                 virtual/glu[abi_x86_32(-)]
  57                 virtual/opengl[abi_x86_32(-)]
  58         )
  59         png? ( media-libs/libpng:0[abi_x86_32(-)] )
  60         scanner? ( media-gfx/sane-backends[abi_x86_32(-)] )
  61         ssl? ( dev-libs/openssl:0[abi_x86_32(-)] )
  62         v4l? ( media-libs/libv4l[abi_x86_32(-)] )
  63         media-libs/alsa-lib[abi_x86_32(-)]
  64         >=media-libs/freetype-2.0.0[abi_x86_32(-)]
  65         media-libs/mesa[abi_x86_32(-)]
  66         sys-apps/util-linux[abi_x86_32(-)]
  67         sys-libs/ncurses:5/5[abi_x86_32(-)]
  68         sys-libs/zlib[abi_x86_32(-)]
  69         x11-libs/libICE[abi_x86_32(-)]
  70         x11-libs/libSM[abi_x86_32(-)]
  71         x11-libs/libX11[abi_x86_32(-)]
  72         x11-libs/libXau[abi_x86_32(-)]
  73         x11-libs/libXdmcp[abi_x86_32(-)]
  74         x11-libs/libXext[abi_x86_32(-)]
  75         x11-libs/libXi[abi_x86_32(-)]
  76         x11-libs/libXrandr[abi_x86_32(-)]
  77         x11-libs/libXxf86vm[abi_x86_32(-)]
  78         x11-libs/libxcb[abi_x86_32(-)]"
  79
  80 pkg_nofetch() {
  81         einfo "Please visit ${HOMEPAGE}"
  82         einfo "and place ${A} in ${DISTDIR}"
  83 }
  84
  85 src_unpack() {
  86         # self unpacking zip archive; unzip warns about the exe stuff
  87         unpack_zip ${A}
  88 }
  89
  90 src_prepare() {
  91         python_fix_shebang .
  92         sed -e 's:/usr/local/etc/xdg /etc/xdg::' -i "${WORKDIR}/bin/locate_gui.sh" \
  93                  || die "Could not patch ${WORKDIR}/bin/locate_gui.sh"
  94
  95         # Remove unnecessary files
  96         rm -r license.txt guis/ || die "Could not remove files"
  97         use doc || rm -r doc/ || die "Could not remove files"
  98 }
  99
 100 src_install() {
 101         # Install crossover symlink, bug #476314
 102         dosym ../cxoffice/bin/crossover /opt/bin/crossover
 103
 104         # Install documentation
 105         dodoc README changelog.txt
 106         rm README changelog.txt || die "Could not remove README and changelog.txt"
 107
 108         # Install files
 109         dodir /opt/cxoffice
 110         cp -r ./* "${ED}opt/cxoffice" \
 111                 || die "Could not install into ${ED}opt/cxoffice"
 112
 113         # Install configuration file
 114         insinto /opt/cxoffice/etc
 115         doins share/crossover/data/cxoffice.conf
 116
 117         # Install requisite directories for menus
 118         dodir "/usr/share/applications"
 119         dodir "/etc/xdg/menus/applications-merged"
 120
 121         # Install menus
 122         XDG_CONFIG_DIRS="${ED}etc/xdg" \
 123                 XDG_DATA_DIRS="${ED}usr/share" \
 124                 "${ED}opt/cxoffice/bin/cxmenu" --crossover --install \
 125                 || die "Could not install menus"
 126
 127         # Fix menus
 128         sed -e "s:${ED}:/:" -i "${ED}usr/share/applications/"* \
 129                 || die "Could not fix menus"
 130 }