app-emulation/conmon/conmon-2.0.15.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 EGIT_COMMIT="1bddbf7051a973f4a4fecf06faa0c48e82f1e9e1"
   7 DESCRIPTION="An OCI container runtime monitor"
   8 HOMEPAGE="https://github.com/containers/conmon"
   9 SRC_URI="https://github.com/containers/conmon/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="Apache-2.0"
  12 SLOT="0"
  13 KEYWORDS="~amd64"
  14 IUSE="systemd"
  15 RESTRICT="test"
  16
  17 RDEPEND="dev-libs/glib:=
  18         systemd? ( sys-apps/systemd:= )"
  19 DEPEND="${RDEPEND}"
  20
  21 S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
  22
  23 src_prepare() {
  24         default
  25
  26         if ! use systemd; then
  27                 sed -e 's| $(PKG_CONFIG) --exists libsystemd-journal | false |' \
  28                         -e 's| $(PKG_CONFIG) --exists libsystemd | false |' \
  29                         -i Makefile || die
  30         fi
  31 }
  32
  33 src_compile() {
  34         emake GIT_COMMIT="${EGIT_COMMIT}" \
  35                 all
  36 }
  37
  38 src_install() {
  39         emake DESTDIR="${D}" \
  40                 PREFIX="/usr" \
  41                 install
  42         dodir /usr/libexec/podman
  43         ln "${ED}/usr/"{bin,libexec/podman}/conmon || die
  44         dodoc README.md
  45 }