app-emacs/zenirc/zenirc-2.112-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit readme.gentoo elisp
   7
   8 DESCRIPTION="A full-featured scriptable IRC client for the Emacs text editor"
   9 HOMEPAGE="http://www.zenirc.org/"
  10 SRC_URI="ftp://ftp.zenirc.org/pub/zenirc/${P}.tar.gz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15
  16 SITEFILE="50${PN}-gentoo.el"
  17
  18 src_configure() {
  19         # econf won't work because of unknown options
  20         ./configure --prefix="${EPREFIX}/usr/" || die "configure failed"
  21 }
  22
  23 src_compile() {
  24         default
  25 }
  26
  27 src_install() {
  28         elisp-install ${PN} src/*.el src/*.elc
  29         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  30
  31         doinfo doc/zenirc.info
  32         dodoc BUGS INSTALL NEWS README TODO
  33
  34         cd doc
  35         docinto doc
  36         dodoc 666.conspiracy FAQ README-OLD ctcp.doc irc-operators \
  37                 server-list tao-of-irc tour.of.irc undernet
  38
  39         DOC_CONTENTS="Refer to the Info documentation and
  40                 ${SITELISP}/${PN}/zenirc-example.el for customization hints."
  41         readme.gentoo_create_doc
  42 }