app-emacs/wanderlust/wanderlust-2.15.9_p20190623.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp
   7
   8 DESCRIPTION="Yet Another Message Interface on Emacsen"
   9 HOMEPAGE="https://github.com/wanderlust/wanderlust"
  10 GITHUB_SHA1="b9a529a54b9e7eafa4ed230ad28efffe0d25a20e"
  11 SRC_URI="https://github.com/wanderlust/wanderlust/archive/${GITHUB_SHA1}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 ~ia64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  16 IUSE="bbdb ssl l10n_ja"
  17
  18 DEPEND=">=app-emacs/apel-10.8
  19         >=app-emacs/flim-1.14.9
  20         >=app-emacs/semi-1.14.7
  21         bbdb? ( app-emacs/bbdb )"
  22 RDEPEND="${DEPEND}"
  23
  24 S="${WORKDIR}/${PN}-${GITHUB_SHA1}"
  25 SITEFILE="50${PN}-gentoo.el"
  26
  27 src_configure() {
  28         local lang="\"en\""
  29         use l10n_ja && lang="${lang} \"ja\""
  30         echo "(setq wl-info-lang '(${lang}) wl-news-lang '(${lang}))" >>WL-CFG
  31         use ssl && echo "(setq wl-install-utils t)" >>WL-CFG
  32 }
  33
  34 src_compile() {
  35         emake
  36         emake info
  37 }
  38
  39 src_install() {
  40         emake \
  41                 LISPDIR="${ED}${SITELISP}" \
  42                 PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
  43                 install
  44
  45         elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
  46
  47         insinto "${SITEETC}/wl/samples/en"
  48         doins samples/en/*
  49         doinfo doc/wl*.info
  50         dodoc BUGS ChangeLog INSTALL NEWS README.md
  51
  52         if use l10n_ja; then
  53                 insinto "${SITEETC}/wl/samples/ja"
  54                 doins samples/ja/*
  55                 dodoc BUGS.ja INSTALL.ja NEWS.ja README.ja
  56         fi
  57 }