app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit elisp
   8
   9 DESCRIPTION="Yet Another Message Interface on Emacsen"
  10 HOMEPAGE="https://github.com/wanderlust/wanderlust
  11         http://emacswiki.org/emacs/WanderLust"
  12 SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  17 IUSE="bbdb ssl linguas_ja"
  18
  19 DEPEND=">=app-emacs/apel-10.6
  20         virtual/emacs-flim
  21         app-emacs/semi
  22         bbdb? ( app-emacs/bbdb )"
  23 RDEPEND="${DEPEND}"
  24
  25 S="${WORKDIR}/${PN}"
  26 SITEFILE="50${PN}-gentoo.el"
  27
  28 src_configure() {
  29         local lang="\"en\""
  30         use linguas_ja && lang="${lang} \"ja\""
  31         echo "(setq wl-info-lang '(${lang}) wl-news-lang '(${lang}))" >>WL-CFG
  32         use ssl && echo "(setq wl-install-utils t)" >>WL-CFG
  33 }
  34
  35 src_compile() {
  36         emake
  37         emake info
  38 }
  39
  40 src_install() {
  41         emake \
  42                 LISPDIR="${ED}${SITELISP}" \
  43                 PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
  44                 install
  45
  46         elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
  47
  48         insinto "${SITEETC}/wl/samples/en"
  49         doins samples/en/*
  50         doinfo doc/wl*.info
  51         dodoc BUGS ChangeLog INSTALL NEWS README.md
  52
  53         if use linguas_ja; then
  54                 insinto "${SITEETC}/wl/samples/ja"
  55                 doins samples/ja/*
  56                 dodoc BUGS.ja INSTALL.ja NEWS.ja README.ja
  57         fi
  58 }