app-emacs/slime/slime-2.20-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit elisp
   7
   8 DESCRIPTION="SLIME, the Superior Lisp Interaction Mode (Extended)"
   9 HOMEPAGE="http://common-lisp.net/project/slime/"
  10 SRC_URI="https://github.com/slime/slime/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2 xref? ( xref.lisp )"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~sparc ~x86"
  15 IUSE="doc xref"
  16 RESTRICT=test # tests fail to contact sbcl
  17
  18 RDEPEND="virtual/commonlisp
  19         dev-lisp/asdf"
  20 DEPEND="${RDEPEND}
  21         >=sys-apps/texinfo-5.1
  22         doc? ( virtual/texi2dvi )"
  23
  24 CLPACKAGE=swank
  25 CLSYSTEMS=swank
  26 SITEFILE=70${PN}-gentoo.el
  27
  28 PATCHES=(
  29         # Should be fixed in >=app-emacs/slime-2.20
  30         "${FILESDIR}/${PN}-2.20-fix-doc-build.patch"
  31 )
  32
  33 src_prepare() {
  34         default
  35         # Remove xref.lisp (which is non-free) unless USE flag is set
  36         use xref || rm -f xref.lisp
  37 }
  38
  39 src_compile() {
  40         elisp-compile *.el
  41         BYTECOMPFLAGS="${BYTECOMPFLAGS} -L contrib -l slime" \
  42                 elisp-compile contrib/*.el lib/*.el
  43
  44         emake -C doc slime.info
  45         if use doc ; then
  46                 VARTEXFONTS="${T}"/fonts \
  47                         emake -C doc all
  48         fi
  49 }
  50
  51 src_install() {
  52         # Install core
  53         elisp-install ${PN} *.{el,elc,lisp}
  54
  55         # Install contribs
  56         elisp-install ${PN}/contrib/ contrib/*.{el,elc,lisp,scm,goo}
  57
  58         # Install lib
  59         elisp-install ${PN}/lib/ lib/*.{el,elc}
  60
  61         # Install swank
  62         elisp-install ${PN}/swank/ swank/*.lisp
  63
  64         elisp-site-file-install "${FILESDIR}"/${SITEFILE}
  65         # Install docs
  66         dodoc README.md CONTRIBUTING.md NEWS PROBLEMS
  67         newdoc contrib/README.md README-contrib.md
  68         doinfo doc/slime.info
  69         use doc && dodoc doc/*.pdf
  70
  71         # Bug #656760
  72         touch "${ED}${SITELISP}/${PN}/lib/.nosearch" || die
  73 }