app-emacs/rudel/rudel-0.3_pre20110721-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 NEED_EMACS=24
   6
   7 inherit readme.gentoo-r1 elisp
   8
   9 DESCRIPTION="Collaborative editing environment for GNU Emacs"
  10 HOMEPAGE="http://rudel.sourceforge.net/
  11         https://www.emacswiki.org/emacs/Rudel"
  12 # snapshot of bzr://rudel.bzr.sourceforge.net/bzrroot/rudel/trunk
  13 SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
  14
  15 LICENSE="GPL-3+"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18
  19 S="${WORKDIR}/${PN}"
  20 ELISP_PATCHES="${P}-emacs25.patch"
  21 SITEFILE="60${PN}-gentoo.el"
  22
  23 src_compile() {
  24         ${EMACS} ${EMACSFLAGS} -l rudel-compile.el || die
  25 }
  26
  27 src_install() {
  28         local dir
  29
  30         for dir in . adopted infinote jupiter obby socket telepathy tls \
  31                 xmpp zeroconf
  32         do
  33                 insinto "${SITELISP}/${PN}/${dir}"
  34                 doins ${dir}/*.{el,elc}
  35         done
  36
  37         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  38
  39         insinto "${SITEETC}/${PN}"
  40         doins -r icons
  41
  42         dodoc README INSTALL ChangeLog TODO doc/card.pdf
  43
  44         DOC_CONTENTS="Connections to Gobby servers require the gnutls-cli program
  45                 (net-libs/gnutls).
  46                 \\n\\nThe Avahi daemon (net-dns/avahi) is required for automatic
  47                 session discovery and advertising."
  48         readme.gentoo_create_doc
  49 }