app-emacs/rudel/rudel-0.3.1.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 NEED_EMACS=24
   6
   7 inherit readme.gentoo-r1 elisp
   8
   9 DESCRIPTION="Collaborative editing environment for GNU Emacs"
  10 HOMEPAGE="http://rudel.sourceforge.net/
  11         https://www.emacswiki.org/emacs/Rudel"
  12 SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz" # from GNU ELPA
  13
  14 LICENSE="GPL-3+"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 ELISP_REMOVE="${PN}-pkg.el"
  19 SITEFILE="60${PN}-gentoo-${PV}.el"
  20
  21 src_install() {
  22         elisp-install ${PN} *.el *.elc
  23         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  24
  25         insinto "${SITEETC}/${PN}"
  26         doins -r icons
  27
  28         dodoc README INSTALL ChangeLog TODO doc/card.pdf
  29
  30         DOC_CONTENTS="Connections to Gobby servers require the gnutls-cli program
  31                 (net-libs/gnutls[tools]).
  32                 \\n\\nThe Avahi daemon (net-dns/avahi) is required for automatic
  33                 session discovery and advertising."
  34         readme.gentoo_create_doc
  35 }