app-emacs/pymacs/pymacs-0.25-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 PYTHON_COMPAT=( python{2_7,3_5,3_6} )
   6
   7 inherit elisp distutils-r1 vcs-snapshot
   8
   9 DESCRIPTION="A tool that allows both-side communication beetween Python and Emacs Lisp"
  10 HOMEPAGE="https://www.emacswiki.org/emacs/PyMacs"
  11 SRC_URI="https://github.com/pinard/Pymacs/tarball/v${PV} -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="amd64 arm ~hppa ia64 ppc ppc64 ~s390 ~sh x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  16 IUSE="doc"
  17
  18 DEPEND="doc? (
  19                 >=dev-python/docutils-0.7
  20                 virtual/latex-base )
  21 "
  22 RDEPEND=""
  23
  24 DISTUTILS_IN_SOURCE_BUILD=1
  25 SITEFILE="50${PN}-gentoo.el"
  26
  27 python_prepare_all() {
  28         sed \
  29                 -e '/pymacs-python-command/s/@PYTHON@/python/' \
  30                 -i pymacs.el.in || die
  31         distutils-r1_python_prepare_all
  32 }
  33
  34 # called by distutils-r1 for every python implementation
  35 python_configure() {
  36         # pre-process the files but don't run distutils
  37         emake PYSETUP=: PYTHON=${EPYTHON}
  38 }
  39
  40 # called once
  41 python_compile_all() {
  42         elisp_src_compile
  43         if use doc; then
  44                 VARTEXFONTS="${T}"/fonts emake RST2LATEX=rst2latex.py pymacs.pdf
  45         fi
  46 }
  47
  48 python_install_all() {
  49         elisp_src_install
  50
  51         distutils-r1_python_install_all
  52         dodoc pymacs.rst
  53         use doc && dodoc pymacs.pdf
  54 }