app-emacs/nxml-svg-schemas/nxml-svg-schemas-1.1.20081123-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp
   7
   8 DESCRIPTION="Extension for nxml-mode with SVG 1.1 schemas"
   9 HOMEPAGE="http://www.w3.org/TR/SVG11/"
  10 # original SRC_URI is http://www.w3.org/Graphics/SVG/1.1/rng/rng.zip
  11 # but since it's unversioned, I versioned it and got it locally.
  12 SRC_URI="http://www.flameeyes.eu/gentoo-distfiles/w3c-svg-rng-${PV}.zip"
  13
  14 LICENSE="HPND"
  15 # In a future we might have 1.2 schemas too, but for now we can only
  16 # install this one anyway because the schemas.xml syntax is not
  17 # sophisticated enough.
  18 SLOT="1.1"
  19 KEYWORDS="amd64 x86"
  20
  21 # Yes this requires Java, but I'd rather not repackage this, if you
  22 # know something better in C, I'll be glad to use that.
  23 BDEPEND="app-arch/unzip
  24         app-text/trang"
  25
  26 S="${WORKDIR}"
  27 SITEFILE="60${PN}-gentoo.el"
  28
  29 src_prepare() {
  30         elisp_src_prepare
  31         # we don't need the doctype for our work
  32         sed -i -e '/DOCTYPE grammar/d' *.rng || die "sed failed"
  33 }
  34
  35 src_compile() {
  36         emake -f "${FILESDIR}/Makefile-trang"
  37 }
  38
  39 src_install() {
  40         insinto "${SITEETC}/${PN}"
  41         doins "${FILESDIR}/schemas.xml" *.rnc
  42         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  43 }