app-emacs/jde/jde-2.4.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 elisp eutils
   9
  10 DESCRIPTION="Java Development Environment for Emacs"
  11 HOMEPAGE="http://jdee.sourceforge.net/"
  12 # snapshot of svn://svn.code.sf.net/p/jdee/code/branches/2.4.1 (rev 292)
  13 # (upstream's distfile misses build.xml)
  14 SRC_URI="mirror://gentoo/jdee-${PV}.tar.xz"
  15
  16 LICENSE="GPL-2+"
  17 SLOT="0"
  18 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  19
  20 RDEPEND=">=virtual/jdk-1.3
  21         app-emacs/elib
  22         dev-java/bsh:0
  23         dev-java/junit:0
  24         dev-util/checkstyle:0"
  25 DEPEND="${RDEPEND}
  26         dev-java/ant-contrib:0"
  27
  28 S="${WORKDIR}/jdee-${PV}"
  29 SITEFILE="70${PN}-gentoo.el"
  30
  31 pkg_setup() {
  32         java-pkg-2_pkg_setup
  33         elisp_pkg_setup
  34 }
  35
  36 src_prepare() {
  37         epatch "${FILESDIR}/${PN}-2.4.0.1-fix-paths-gentoo.patch"
  38         epatch "${FILESDIR}/${PN}-2.4.0.1-classpath-gentoo.patch"
  39         epatch "${FILESDIR}/${PN}-2.4.1-doc-directory.patch"
  40
  41         local bshjar csjar
  42         bshjar=$(java-pkg_getjar --build-only bsh bsh.jar) || die
  43         csjar=$(java-pkg_getjar --build-only checkstyle checkstyle.jar) || die
  44         sed -e "s:@BSH_JAR@:${bshjar}:;s:@CHECKSTYLE_JAR@:${csjar}:" \
  45                 -e "s:@PF@:${PF}:" "${FILESDIR}/${SITEFILE}" >"${SITEFILE}" || die
  46
  47         cd java/lib || die
  48         java-pkg_jar-from --build-only checkstyle checkstyle.jar checkstyle-all.jar
  49         java-pkg_jar-from junit
  50         java-pkg_jar-from bsh
  51 }
  52
  53 src_compile() {
  54         ANT_TASKS="ant-contrib" \
  55                 eant -Delib.dir="${EPREFIX}${SITELISP}/elib" \
  56                 bindist $(usex doc source-doc "")
  57 }
  58
  59 src_install() {
  60         local dist="dist/jdee-${PV%_*}"
  61
  62         java-pkg_dojar ${dist}/java/lib/jde.jar
  63         insinto "${JAVA_PKG_SHAREPATH}"
  64         doins -r java/bsh-commands
  65
  66         use source && java-pkg_dosrc java/src/*
  67         use doc && java-pkg_dojavadoc ${dist}/doc/java/api
  68
  69         elisp-install ${PN} ${dist}/lisp/*.{el,elc}
  70         elisp-site-file-install "${SITEFILE}"
  71
  72         dobin ${dist}/lisp/jtags
  73
  74         dohtml -r doc/html/*
  75 }