app-emacs/haskell-mode/haskell-mode-13.07.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit elisp
   8
   9 DESCRIPTION="Mode for editing (and running) Haskell programs in Emacs"
  10 HOMEPAGE="http://projects.haskell.org/haskellmode-emacs/
  11         http://www.haskell.org/haskellwiki/Emacs#Haskell-mode"
  12 SRC_URI="https://github.com/haskell/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-3+ FDL-1.2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc ~sparc x86"
  17
  18 SITEFILE="50${PN}-gentoo.el"
  19 ELISP_TEXINFO="haskell-mode.texi"
  20 DOCS="NEWS README.md examples/*.hs examples/init.el"
  21
  22 src_prepare() {
  23         # We install the logo in SITEETC, not in SITELISP
  24         # https://github.com/haskell/haskell-mode/issues/102
  25         sed -i -e "/defconst haskell-process-logo/{n;" \
  26                 -e "s:(.*\"\\(.*\\)\".*):\"${SITEETC}/${PN}/\\1\":}" \
  27                 haskell-process.el || die
  28 }
  29
  30 src_compile() {
  31         elisp_src_compile
  32         elisp-make-autoload-file haskell-site-file.el
  33 }
  34
  35 src_test() {
  36         # perform tests in a separate directory #504660
  37         mkdir test && cp *.el Makefile test || die
  38         emake -C test check
  39 }
  40
  41 src_install() {
  42         elisp_src_install
  43         insinto "${SITEETC}/${PN}"
  44         doins logo.svg
  45 }