app-emacs/ess/ess-17.11.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit elisp readme.gentoo-r1
   7
   8 DESCRIPTION="Emacs Speaks Statistics"
   9 HOMEPAGE="http://ess.r-project.org/"
  10 SRC_URI="http://ess.r-project.org/downloads/ess/${P}.tgz"
  11
  12 LICENSE="GPL-2+ GPL-3+ Texinfo-manual"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm ppc x86 ~amd64-linux ~x86-linux ~x86-macos"
  15 RESTRICT="test"
  16
  17 DEPEND="app-text/texi2html
  18         virtual/latex-base"
  19
  20 SITEFILE="50${PN}-gentoo.el"
  21
  22 src_compile() {
  23         default
  24 }
  25
  26 src_install() {
  27         emake PREFIX="${ED}/usr" \
  28                 INFODIR="${ED}/usr/share/info" \
  29                 LISPDIR="${ED}${SITELISP}/ess" \
  30                 DOCDIR="${ED}/usr/share/doc/${PF}" \
  31                 install
  32
  33         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  34
  35         # Most documentation is installed by the package's build system.
  36         rm -f "${ED}${SITELISP}/${PN}/ChangeLog"
  37         dodoc ChangeLog *NEWS doc/{TODO,ess-intro.pdf}
  38         newdoc doc/ChangeLog ChangeLog-doc
  39         newdoc lisp/ChangeLog ChangeLog-lisp
  40
  41         DOC_CONTENTS="Please see /usr/share/doc/${PF} for the complete
  42                 documentation. Usage hints are in ${SITELISP}/${PN}/ess-site.el ."
  43         readme.gentoo_create_doc
  44 }