app-emacs/emms/emms-5.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp toolchain-funcs
   7
   8 DESCRIPTION="The Emacs Multimedia System"
   9 HOMEPAGE="https://www.gnu.org/software/emms/
  10         https://www.emacswiki.org/emacs/EMMS"
  11 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-3+ FDL-1.1+"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~ppc ~sparc ~x86"
  16
  17 RDEPEND="media-libs/taglib"
  18 DEPEND="${RDEPEND}"
  19
  20 # EMMS can use almost anything for playing media files therefore the dependency
  21 # possibilities are so broad that we refrain from setting anything explicitly
  22 # in DEPEND/RDEPEND.
  23
  24 SITEFILE="50${PN}-gentoo.el"
  25
  26 src_compile() {
  27         emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
  28                 all emms-print-metadata
  29 }
  30
  31 src_install() {
  32         elisp-install ${PN} lisp/*.{el,elc}
  33         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  34         doinfo doc/emms.info*
  35         dobin src/emms-print-metadata
  36         doman emms-print-metadata.1
  37         dodoc AUTHORS ChangeLog NEWS README THANKGNU
  38 }