app-emacs/emms/emms-3.0-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit elisp toolchain-funcs
   8
   9 DESCRIPTION="The Emacs Multimedia System"
  10 HOMEPAGE="https://www.gnu.org/software/emms/
  11         http://www.emacswiki.org/emacs/EMMS"
  12 SRC_URI="https://www.gnu.org/software/emms/download/${P}.tar.gz"
  13
  14 LICENSE="GPL-3+ FDL-1.1+"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc ~sparc ~x86"
  17
  18 DEPEND="media-libs/taglib"
  19 RDEPEND="${DEPEND}"
  20
  21 # EMMS can use almost anything for playing media files therefore the dependency
  22 # possibilities are so broad that we refrain from setting anything explicitly
  23 # in DEPEND/RDEPEND.
  24
  25 ELISP_PATCHES="${P}-Makefile.patch
  26         ${P}-texinfo-5.patch"
  27 SITEFILE="50${PN}-gentoo.el"
  28
  29 src_compile() {
  30         emake CC="$(tc-getCC)" \
  31                 EMACS=emacs \
  32                 all emms-print-metadata
  33 }
  34
  35 src_install() {
  36         elisp-install ${PN} *.{el,elc}
  37         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  38         doinfo *.info*
  39         dobin *-wrapper emms-print-metadata
  40         dodoc AUTHORS ChangeLog FAQ NEWS README RELEASE
  41 }