app-emacs/ecb/ecb-2.50_pre20170728.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp readme.gentoo-r1
   7
   8 DESCRIPTION="Source code browser for Emacs"
   9 HOMEPAGE="http://ecb.sourceforge.net/"
  10 # snapshot of https://github.com/ecb-home/ecb.git, created with "make distrib"
  11 SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  16 IUSE="java"
  17
  18 RDEPEND="java? ( app-emacs/jde )"
  19 DEPEND="${RDEPEND}"
  20
  21 S="${WORKDIR}/${PN}-${PV%_*}"
  22 SITEFILE="70${PN}-gentoo.el"
  23 DOC_CONTENTS="ECB is autoloaded in site-gentoo.el. Add the line
  24         \n\t(require 'ecb)
  25         \nto your ~/.emacs file to enable all features on Emacs startup."
  26
  27 src_prepare() {
  28         eapply "${FILESDIR}"/${PN}-2.32-gentoo.patch
  29         sed -i -e "s:@PF@:${PF}:" ecb-help.el || die "sed failed"
  30         eapply_user
  31 }
  32
  33 src_compile() {
  34         local loadpath
  35         use java && loadpath="${EPREFIX}${SITELISP}"/{elib,jde,jde/lisp}
  36         emake LOADPATH="${loadpath}"
  37 }
  38
  39 src_install() {
  40         elisp_src_install
  41
  42         insinto "${SITEETC}/${PN}"
  43         doins -r ecb-images
  44
  45         doinfo info-help/ecb.info*
  46         dodoc NEWS README RELEASE_NOTES
  47         docinto html
  48         dodoc html-help/*.html
  49 }