app-emacs/ddskk/ddskk-16.2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 USE_RUBY="ruby23 ruby24 ruby25"
   6 NEED_EMACS="24"
   7
   8 inherit elisp ruby-single
   9
  10 DESCRIPTION="One Japanese input methods on Emacs"
  11 HOMEPAGE="http://openlab.ring.gr.jp/skk/"
  12 SRC_URI="http://openlab.ring.gr.jp/skk/maintrunk/${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
  17 IUSE="ruby"
  18
  19 DEPEND=""
  20 RDEPEND="|| (
  21                 app-i18n/skk-jisyo
  22                 virtual/skkserv
  23         )
  24         ruby? ( ${RUBY_DEPS} )"
  25
  26 SITEFILE="50${PN}-gentoo.el"
  27
  28 src_prepare() {
  29         echo "(setq PREFIX \"${ED}/usr\")" >>SKK-CFG
  30         echo "(setq SKK_LISPDIR \"${ED}/${SITELISP}/${PN}\")" >>SKK-CFG
  31
  32         echo "(add-to-list 'load-path (expand-file-name \"..\"))" >> nicola/NICOLA-DDSKK-CFG
  33
  34         default
  35
  36         rm -f skk-lookup.el
  37         mv {bayesian,tut-code}/*.el .
  38 }
  39
  40 src_compile() {
  41         emake elc info
  42
  43         emake -C nicola
  44 }
  45
  46 src_install () {
  47         local lispdir=${SITELISP}/${PN}
  48         emake install-elc
  49         elisp-compile "${ED}"/${lispdir}/skk-setup.el
  50         rm -f "${ED}"/${lispdir}/leim-list.el
  51         elisp-site-file-install "${FILESDIR}"/${SITEFILE}
  52
  53         dodoc ChangeLog* README.md READMEs/{AUTHORS,CODENAME,Contributors,FAQ,NEWS,PROPOSAL,TODO}*
  54         doinfo doc/skk.info
  55
  56         local exts=( nicola tut-code ) d f
  57         elisp-install ${PN} nicola/*.{el,elc}
  58         if use ruby; then
  59                 dobin bayesian/bskk
  60                 exts+=( bayesian )
  61         fi
  62         for d in ${exts[@]}; do
  63                 docinto ${d}
  64                 for f in ${d}/{ChangeLog,README}*; do
  65                         [[ -s ${f} ]] && dodoc ${f}
  66                 done
  67         done
  68 }