app-emacs/chess/chess-2.0.4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 NEED_EMACS=24
   7
   8 inherit elisp
   9
  10 DESCRIPTION="A chess client and library for Emacs"
  11 HOMEPAGE="http://elpa.gnu.org/packages/chess.html
  12         http://www.emacswiki.org/emacs/ChessMode"
  13 # Taken from http://elpa.gnu.org/packages/${P}.tar
  14 SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz
  15         mirror://gentoo/emacs-chess-sounds-${PV%.*}.tar.bz2
  16         mirror://gentoo/emacs-chess-pieces-${PV%.*}.tar.bz2"
  17
  18 LICENSE="GPL-3+ FDL-1.3+"
  19 SLOT="0"
  20 KEYWORDS="amd64 ppc x86"
  21
  22 # Free alternatives first, otherwise follow the ordering in the upstream
  23 # chess-default-engine (in chess.el). Rearrange chess-default-engine in
  24 # the site-init file accordingly.
  25 RDEPEND="|| ( games-board/stockfish
  26                 games-board/fruit
  27                 games-board/gnuchess
  28                 games-board/phalanx
  29                 games-board/sjeng
  30                 games-board/crafty )"
  31
  32 ELISP_REMOVE="chess-pkg.el"
  33 SITEFILE="50${PN}-gentoo-${PV}.el"
  34 DOCS="AUTHORS NEWS TODO"
  35
  36 src_install() {
  37         elisp_src_install
  38         doinfo chess.info
  39         insinto "${SITEETC}/${PN}"
  40         doins chess-eco.fen chess-polyglot.bin
  41         doins -r "${WORKDIR}"/{sounds,pieces}
  42 }