app-emacs/bbdb/bbdb-3.1.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit elisp autotools
   7
   8 DESCRIPTION="The Insidious Big Brother Database"
   9 HOMEPAGE="https://savannah.nongnu.org/projects/bbdb/"
  10 SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3+ GPL-1+ FDL-1.3+"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
  15 IUSE="tex vm"
  16 RESTRICT="test" #631700
  17
  18 DEPEND="tex? ( virtual/tex-base )
  19         vm? ( app-emacs/vm )"
  20 RDEPEND="${DEPEND}"
  21
  22 SITEFILE="50${PN}-gentoo-${PV}.el"
  23 TEXMF="/usr/share/texmf-site"
  24
  25 src_prepare() {
  26         epatch "${FILESDIR}"/${P}-no-init.patch
  27         eautoreconf
  28 }
  29
  30 src_configure() {
  31         econf \
  32                 --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
  33                 "$(use_with vm vm-dir "${EPREFIX}${SITELISP}/vm")"
  34 }
  35
  36 src_compile() {
  37         emake -C lisp
  38 }
  39
  40 src_install() {
  41         emake -C lisp DESTDIR="${D}" install
  42         elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  43         doinfo doc/*.info*
  44         dodoc AUTHORS ChangeLog NEWS README TODO
  45
  46         if use tex; then
  47                 insinto "${TEXMF}"/tex/plain/${PN}
  48                 doins tex/*.tex
  49         fi
  50 }
  51
  52 pkg_postinst() {
  53         elisp-site-regen
  54         use tex && texconfig rehash
  55 }
  56
  57 pkg_postrm() {
  58         elisp-site-regen
  59         use tex && texconfig rehash
  60 }