app-emacs/auctex/auctex-12.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 NEED_EMACS=24
   6
   7 inherit elisp
   8
   9 DESCRIPTION="Extensible package for writing and formatting TeX files in Emacs"
  10 HOMEPAGE="https://www.gnu.org/software/auctex/"
  11 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-3+ FDL-1.3+"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~arm ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
  16 IUSE="preview-latex"
  17
  18 RDEPEND="virtual/latex-base
  19         preview-latex? (
  20                 app-text/dvipng
  21                 app-text/ghostscript-gpl
  22         )"
  23 BDEPEND="${RDEPEND}"
  24
  25 TEXMF="/usr/share/texmf-site"
  26
  27 src_configure() {
  28         econf \
  29                 --with-emacs \
  30                 --with-auto-dir="${EPREFIX}/var/lib/auctex" \
  31                 --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
  32                 --with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
  33                 --with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
  34                 --with-texmf-dir="${EPREFIX}${TEXMF}" \
  35                 --disable-build-dir-test \
  36                 $(use_enable preview-latex preview)
  37 }
  38
  39 src_compile() {
  40         export VARTEXFONTS="${T}"/fonts
  41         emake
  42 }
  43
  44 src_install() {
  45         emake -j1 DESTDIR="${D}" install
  46         elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
  47         if use preview-latex; then
  48                 elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
  49         fi
  50         dodoc ChangeLog* CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
  51 }
  52
  53 pkg_postinst() {
  54         use preview-latex && texmf-update
  55         elisp-site-regen
  56 }
  57
  58 pkg_postrm() {
  59         use preview-latex && texmf-update
  60         elisp-site-regen
  61 }