app-emacs/auctex/auctex-11.92.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit elisp
   7
   8 DESCRIPTION="Extensible package for writing and formatting TeX files in Emacs"
   9 HOMEPAGE="https://www.gnu.org/software/auctex/"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3+ FDL-1.3+"
  13 SLOT="0"
  14 KEYWORDS="amd64 arm ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
  15 IUSE="preview-latex"
  16
  17 DEPEND="virtual/latex-base
  18         preview-latex? (
  19                 app-text/dvipng
  20                 app-text/ghostscript-gpl
  21         )"
  22 RDEPEND="${DEPEND}"
  23
  24 TEXMF="/usr/share/texmf-site"
  25
  26 src_configure() {
  27         econf --with-emacs \
  28                 --with-auto-dir="${EPREFIX}/var/lib/auctex" \
  29                 --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
  30                 --with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
  31                 --with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
  32                 --with-texmf-dir="${EPREFIX}${TEXMF}" \
  33                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  34                 --disable-build-dir-test \
  35                 $(use_enable preview-latex preview)
  36 }
  37
  38 src_compile() {
  39         export VARTEXFONTS="${T}"/fonts
  40         emake
  41 }
  42
  43 src_install() {
  44         emake -j1 DESTDIR="${D}" install
  45         elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
  46         if use preview-latex; then
  47                 elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
  48         fi
  49         dodoc ChangeLog* CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
  50 }
  51
  52 pkg_postinst() {
  53         use preview-latex && texmf-update
  54         elisp-site-regen
  55 }
  56
  57 pkg_postrm(){
  58         use preview-latex && texmf-update
  59         elisp-site-regen
  60 }