app-emacs/auctex/auctex-11.88.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit elisp latex-package
   7
   8 DESCRIPTION="Extensible package for writing and formatting TeX files in Emacs"
   9 HOMEPAGE="https://www.gnu.org/software/auctex/"
  10 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-3+ FDL-1.3+"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
  15 IUSE="preview-latex"
  16
  17 DEPEND="virtual/latex-base
  18         preview-latex? (
  19                 app-text/dvipng
  20                 app-text/ghostscript-gpl
  21         )"
  22 RDEPEND="${DEPEND}"
  23
  24 TEXMF="/usr/share/texmf-site"
  25
  26 src_prepare() {
  27         elisp_src_prepare
  28 }
  29
  30 src_configure() {
  31         EMACS_NAME=emacs EMACS_FLAVOR=emacs econf --disable-build-dir-test \
  32                 --with-auto-dir="${EPREFIX}/var/lib/auctex" \
  33                 --with-lispdir="${EPREFIX}${SITELISP}/${PN}" \
  34                 --with-packagelispdir="${EPREFIX}${SITELISP}/${PN}" \
  35                 --with-packagedatadir="${EPREFIX}${SITEETC}/${PN}" \
  36                 --with-texmf-dir="${EPREFIX}${TEXMF}" \
  37                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  38                 $(use_enable preview-latex preview)
  39 }
  40
  41 src_compile() {
  42         export VARTEXFONTS="${T}"/fonts
  43         emake
  44 }
  45
  46 src_install() {
  47         emake -j1 DESTDIR="${D}" install
  48         elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
  49         if use preview-latex; then
  50                 elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
  51         fi
  52         dodoc ChangeLog CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
  53 }
  54
  55 pkg_postinst() {
  56         # rebuild TeX-inputfiles-database
  57         use preview-latex && latex-package_pkg_postinst
  58         elisp-site-regen
  59 }
  60
  61 pkg_postrm(){
  62         use preview-latex && latex-package_pkg_postrm
  63         elisp-site-regen
  64 }