app-editors/neovim/neovim-0.0.0_pre20150727.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit cmake-utils flag-o-matic
   7
   8 DESCRIPTION="Ambitious vim fork focused on extensibility and agility"
   9 HOMEPAGE="https://github.com/neovim/neovim"
  10 if [[ ${PV} == 9999 ]]; then
  11         inherit git-r3
  12         EGIT_REPO_URI="git://github.com/neovim/neovim.git"
  13 else
  14         SRC_URI="https://dev.gentoo.org/~yngwin/distfiles/${P}.tar.xz"
  15         KEYWORDS="~amd64 ~x86"
  16 fi
  17
  18 LICENSE="Apache-2.0 vim"
  19 SLOT="0"
  20 IUSE="perl python"
  21
  22 CDEPEND="dev-lang/luajit:2
  23         >=dev-libs/libtermkey-0.17
  24         dev-libs/libvterm-neovim
  25         >=dev-libs/unibilium-1.1.1
  26         >=dev-libs/libuv-1.2.0
  27         >=dev-libs/msgpack-0.6.0_pre20150220
  28         dev-lua/lpeg
  29         dev-lua/messagepack"
  30 DEPEND="${CDEPEND}
  31         virtual/libiconv
  32         virtual/libintl"
  33 RDEPEND="${CDEPEND}
  34         perl? ( dev-lang/perl )
  35         python? ( dev-python/neovim-python-client )"
  36
  37 src_prepare() {
  38         # use our system vim dir
  39         sed -e '/^# define SYS_VIMRC_FILE/s|$VIM|'"${EPREFIX}"'/etc/vim|' \
  40                 -i src/nvim/os/unix_defs.h || die
  41         cmake-utils_src_prepare
  42 }
  43
  44 src_configure() {
  45         export USE_BUNDLED_DEPS=OFF
  46         append-cflags "-Wno-error"
  47         append-cppflags "-DNDEBUG -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1"
  48         local mycmakeargs=(
  49                 -DCMAKE_BUILD_TYPE=Release
  50                 -DLIBUNIBILIUM_USE_STATIC=OFF
  51                 -DLIBTERMKEY_USE_STATIC=OFF
  52                 -DLIBVTERM_USE_STATIC=OFF
  53                 )
  54         cmake-utils_src_configure
  55 }
  56
  57 src_install() {
  58         cmake-utils_src_install
  59         # install a default configuration file
  60         insinto /etc/vim
  61         doins "${FILESDIR}"/nvimrc
  62 }