app-editors/latexila/latexila-3.20.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit gnome2 vala
   8
   9 DESCRIPTION="Integrated LaTeX environment for GNOME"
  10 HOMEPAGE="https://wiki.gnome.org/Apps/LaTeXila"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE="+introspection +latexmk rubber"
  16
  17 # gspell-0.1 is required for this cycle
  18 # https://git.gnome.org/browse/latexila/commit/?h=gnome-3-18&id=fd6b77796e304cfb9e31844cf24432d3b2cb6043
  19 COMMON_DEPEND="$(vala_depend)
  20         app-text/enchant
  21         >=app-text/gspell-1.0:0=
  22         >=dev-libs/glib-2.40:2[dbus]
  23         >=dev-libs/libgee-0.10:0.8=
  24         gnome-base/gsettings-desktop-schemas
  25         >=x11-libs/gtk+-3.20:3
  26         >=x11-libs/gtksourceview-3.18:3.0=
  27         x11-libs/gdk-pixbuf:2
  28         x11-libs/libX11
  29         x11-libs/pango
  30         introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
  31 "
  32 RDEPEND="${COMMON_DEPEND}
  33         virtual/latex-base
  34         x11-themes/hicolor-icon-theme
  35         latexmk? ( dev-tex/latexmk )
  36         rubber? ( dev-tex/rubber )
  37 "
  38 DEPEND="${COMMON_DEPEND}
  39         >=dev-util/gtk-doc-am-1.14
  40         >=dev-util/intltool-0.50.1
  41         dev-util/itstool
  42         virtual/pkgconfig
  43 "
  44
  45 src_prepare() {
  46         gnome2_src_prepare
  47         vala_src_prepare
  48 }
  49
  50 src_configure() {
  51         gnome2_src_configure \
  52                 $(use_enable introspection)
  53 }