app-editors/jove/jove-4.16.0.73-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Jonathan's Own Version of Emacs, a light emacs-like editor without LISP bindings"
   9 HOMEPAGE="ftp://ftp.cs.toronto.edu/cs/ftp/pub/hugh/jove-dev/"
  10 SRC_URI="ftp://ftp.cs.toronto.edu/cs/ftp/pub/hugh/jove-dev/${PN}${PV}.tgz"
  11
  12 LICENSE="JOVE"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15 IUSE="doc"
  16
  17 RDEPEND="sys-libs/ncurses:0="
  18 DEPEND="${RDEPEND}"
  19 BDEPEND="virtual/pkgconfig"
  20
  21 S="${WORKDIR}/${PN}${PV}"
  22
  23 PATCHES=(
  24         "${FILESDIR}"/${PN}-4.16.0.70.3.1-getline.patch
  25         "${FILESDIR}"/${P}-build.patch
  26         "${FILESDIR}"/${P}-sendmail.patch
  27         "${FILESDIR}"/${P}-doc.patch
  28 )
  29
  30 src_compile() {
  31         tc-export CC
  32
  33         emake OPTFLAGS="${CFLAGS}" \
  34                 SYSDEFS="-DSYSVR4 -D_XOPEN_SOURCE=500 -D_XOPEN_STREAMS=-1" \
  35                 TERMCAPLIB="$("$(tc-getPKG_CONFIG)" --libs ncurses)"
  36
  37         if use doc; then
  38                 # Full manual (*not* man page)
  39                 emake doc/jove.man
  40         fi
  41 }
  42
  43 src_install() {
  44         emake DESTDIR="${D}" install
  45         keepdir /var/lib/jove/preserve
  46
  47         dodoc README
  48         if use doc; then
  49                 dodoc doc/jove.man
  50         fi
  51 }