app-doc/doxygen/doxygen-1.8.14-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
   6
   7 inherit cmake-utils eutils python-any-r1
   8 if [[ ${PV} = *9999* ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/doxygen/doxygen.git"
  11         SRC_URI=""
  12 else
  13         SRC_URI="https://ftp.stack.nl/pub/users/dimitri/${P}.src.tar.gz"
  14         KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
  15 fi
  16
  17 DESCRIPTION="Documentation system for most programming languages"
  18 HOMEPAGE="https://www.stack.nl/~dimitri/doxygen/"
  19
  20 LICENSE="GPL-2"
  21 SLOT="0"
  22 IUSE="clang debug doc dot doxysearch latex qt5 sqlite userland_GNU"
  23
  24 RDEPEND="app-text/ghostscript-gpl
  25         dev-lang/perl
  26         media-libs/libpng:0=
  27         virtual/libiconv
  28         clang? ( >=sys-devel/clang-4.0.0:= )
  29         dot? (
  30                 media-gfx/graphviz
  31                 media-libs/freetype
  32         )
  33         doxysearch? ( dev-libs/xapian )
  34         latex? (
  35                 dev-texlive/texlive-bibtexextra
  36                 dev-texlive/texlive-fontsextra
  37                 dev-texlive/texlive-fontutils
  38                 dev-texlive/texlive-latex
  39                 dev-texlive/texlive-latexextra
  40         )
  41         qt5? (
  42                 dev-qt/qtgui:5
  43                 dev-qt/qtwidgets:5
  44                 dev-qt/qtxml:5
  45         )
  46         sqlite? ( dev-db/sqlite:3 )
  47         "
  48
  49 REQUIRED_USE="doc? ( latex )"
  50
  51 DEPEND="sys-devel/flex
  52         sys-devel/bison
  53         doc? ( ${PYTHON_DEPS} )
  54         ${RDEPEND}"
  55
  56 # src_test() defaults to make -C testing but there is no such directory (bug #504448)
  57 RESTRICT="test"
  58
  59 PATCHES=(
  60         "${FILESDIR}/${PN}-1.8.9.1-empty-line-sigsegv.patch" #454348
  61         "${FILESDIR}/${PN}-1.8.12-link_with_pthread.patch"
  62 )
  63
  64 DOCS=( LANGUAGE.HOWTO README.md )
  65
  66 pkg_setup() {
  67         use doc && python-any-r1_pkg_setup
  68 }
  69
  70 src_prepare() {
  71         cmake-utils_src_prepare
  72
  73         # Ensure we link to -liconv
  74         if use elibc_FreeBSD && has_version dev-libs/libiconv || use elibc_uclibc; then
  75                 local pro
  76                 for pro in */*.pro.in */*/*.pro.in; do
  77                         echo "unix:LIBS += -liconv" >> "${pro}" || die
  78                 done
  79         fi
  80
  81         # Call dot with -Teps instead of -Tps for EPS generation - bug #282150
  82         sed -i -e '/addJob("ps"/ s/"ps"/"eps"/g' src/dot.cpp || die
  83
  84         # fix pdf doc
  85         sed -i.orig -e "s:g_kowal:g kowal:" \
  86                 doc/maintainers.txt || die
  87
  88         if is-flagq "-O3" ; then
  89                 ewarn
  90                 ewarn "Compiling with -O3 is known to produce incorrectly"
  91                 ewarn "optimized code which breaks doxygen."
  92                 ewarn
  93                 elog
  94                 elog "Continuing with -O2 instead ..."
  95                 elog
  96                 replace-flags "-O3" "-O2"
  97         fi
  98 }
  99
 100 src_configure() {
 101         local mycmakeargs=(
 102                 -Duse_libclang=$(usex clang)
 103                 -Dbuild_doc=$(usex doc)
 104                 -Dbuild_search=$(usex doxysearch)
 105                 -Dbuild_wizard=$(usex qt5)
 106                 -Duse_sqlite3=$(usex sqlite)
 107                 )
 108         use doc && mycmakeargs+=(
 109                 -DDOC_INSTALL_DIR="share/doc/${P}"
 110                 )
 111
 112         cmake-utils_src_configure
 113 }
 114
 115 src_compile() {
 116         cmake-utils_src_compile
 117
 118         if use doc; then
 119                 export VARTEXFONTS="${T}/fonts" # bug #564944
 120
 121                 if ! use dot; then
 122                         sed -i -e "s/HAVE_DOT               = YES/HAVE_DOT    = NO/" \
 123                                 {Doxyfile,doc/Doxyfile} \
 124                                 || die "disabling dot failed"
 125                 fi
 126                 cmake-utils_src_make -C "${BUILD_DIR}" docs
 127         fi
 128 }
 129
 130 src_install() {
 131         cmake-utils_src_install
 132 }