app-crypt/signing-party/signing-party-2.9.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs autotools
   7
   8 DESCRIPTION="A collection of several tools related to OpenPGP"
   9 HOMEPAGE="https://salsa.debian.org/signing-party-team/signing-party"
  10 SRC_URI="mirror://debian/pool/main/s/signing-party/${PN}_${PV}.orig.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15
  16 DEPEND="dev-lang/perl
  17         app-crypt/libmd"
  18 RDEPEND="${DEPEND}
  19         >=app-crypt/gnupg-1.3.92
  20         dev-perl/GnuPG-Interface
  21         dev-perl/Text-Template
  22         dev-perl/MIME-tools
  23         net-mail/qprint
  24         >=dev-perl/MailTools-1.62
  25         dev-perl/Net-IDN-Encode
  26         virtual/mailx
  27         virtual/mta
  28         || (
  29                 dev-perl/libintl-perl
  30                 dev-perl/Text-Iconv
  31                 app-text/recode
  32         )"
  33
  34 src_prepare() {
  35         default
  36
  37         # app-crypt/keylookup
  38         rm -r keylookup || die
  39         sed -i -e 's#keylookup/keylookup##' Makefile || die
  40
  41         # media-gfx/springgraph
  42         rm -r springgraph || die
  43
  44         find . -name Makefile | xargs sed -i -e 's/CFLAGS:=/CFLAGS=/' -e 's/CPPFLAGS:=/CPPFLAGS=/' -e 's/LDFLAGS:=/LDFLAGS=/'
  45
  46         sed -i -e 's/autoreconf/true/g' keyanalyze/Makefile || die
  47         pushd keyanalyze/pgpring
  48         eautoreconf
  49         popd
  50 }
  51
  52 src_compile() {
  53         emake \
  54                 CC="$(tc-getCC)" \
  55                 CPPFLAGS="${CPPFLAGS}" \
  56                 CFLAGS="${CFLAGS}" \
  57                 LDFLAGS="${LDFLAGS}" \
  58                 STRIP=true
  59 }
  60
  61 src_install() {
  62         einstalldocs
  63
  64         # Check Makefile when a new tool is introduced to this package.
  65         # caff
  66         dobin caff/caff caff/pgp-clean caff/pgp-fixkey
  67         docinto caff
  68         dodoc caff/{README*,THANKS,TODO,caffrc.sample}
  69         # gpgdir
  70         dobin gpgdir/gpgdir
  71         docinto gpgdir
  72         dodoc gpgdir/{VERSION,LICENSE,README,INSTALL,CREDITS,ChangeLog*}
  73         # gpg-key2ps
  74         dobin gpg-key2ps/gpg-key2ps
  75         docinto gpg-key2ps
  76         dodoc gpg-key2ps/README
  77         # gpglist
  78         dobin gpglist/gpglist
  79         # gpg-mailkeys
  80         dobin gpg-mailkeys/gpg-mailkeys
  81         docinto gpg-mailkeys
  82         dodoc gpg-mailkeys/{example.gpg-mailkeysrc,README}
  83         # gpgparticipants
  84         dobin gpgparticipants/gpgparticipants
  85         # gpgwrap
  86         dobin gpgwrap/bin/gpgwrap
  87         docinto gpgwrap
  88         dodoc gpgwrap/{LICENSE,NEWS,README}
  89         doman gpgwrap/doc/gpgwrap.1
  90         # gpgsigs
  91         dobin gpgsigs/gpgsigs
  92         insinto /usr/share/signing-party
  93         # keyanalyze
  94         # TODO: some of the scripts are intended for webpages, and not really
  95         # packaging, so they are NOT installed yet.
  96         newbin keyanalyze/pgpring/pgpring pgpring-keyanalyze
  97         dobin keyanalyze/{keyanalyze,process_keys}
  98         docinto keyanalyze
  99         dodoc keyanalyze/{README,Changelog}
 100         # See app-crypt/keylookup instead
 101         #dobin keylookup/keylookup
 102         #docinto keylookup
 103         #dodoc keylookup/NEWS
 104         # sig2dot
 105         dobin sig2dot/sig2dot
 106         dodoc sig2dot/README.sig2dot
 107         # See media-gfx/springgraph instead
 108         #dobin springgraph/springgraph
 109         #dodoc springgraph/README.springgraph
 110         # all other manpages, and the root doc
 111         doman */*.1
 112         dodoc README
 113 }