app-crypt/mit-krb5/mit-krb5-1.18.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit autotools flag-o-matic multilib-minimal python-any-r1 systemd
   8
   9 MY_P="${P/mit-}"
  10 P_DIR=$(ver_cut 1-2)
  11 DESCRIPTION="MIT Kerberos V"
  12 HOMEPAGE="https://web.mit.edu/kerberos/www/"
  13 SRC_URI="https://web.mit.edu/kerberos/dist/krb5/${P_DIR}/${MY_P}.tar.gz"
  14
  15 LICENSE="openafs-krb5-a BSD MIT OPENLDAP BSD-2 HPND BSD-4 ISC RSA CC-BY-SA-3.0 || ( BSD-2 GPL-2+ )"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
  18 IUSE="cpu_flags_x86_aes doc +keyutils libressl lmdb nls openldap +pkinit selinux +threads test xinetd"
  19 RESTRICT="!test? ( test )"
  20
  21 # Test suite requires network access
  22 RESTRICT="test"
  23
  24 DEPEND="
  25         !!app-crypt/heimdal
  26         >=sys-libs/e2fsprogs-libs-1.42.9[${MULTILIB_USEDEP}]
  27         || (
  28                 >=dev-libs/libverto-0.2.5[libev,${MULTILIB_USEDEP}]
  29                 >=dev-libs/libverto-0.2.5[libevent,${MULTILIB_USEDEP}]
  30                 >=dev-libs/libverto-0.2.5[tevent,${MULTILIB_USEDEP}]
  31         )
  32         keyutils? ( >=sys-apps/keyutils-1.5.8:=[${MULTILIB_USEDEP}] )
  33         lmdb? ( dev-db/lmdb )
  34         nls? ( sys-devel/gettext[${MULTILIB_USEDEP}] )
  35         openldap? ( >=net-nds/openldap-2.4.38-r1[${MULTILIB_USEDEP}] )
  36         pkinit? (
  37                 !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
  38                 libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
  39         )
  40         xinetd? ( sys-apps/xinetd )
  41         "
  42 BDEPEND="
  43         ${PYTHON_DEPS}
  44         virtual/yacc
  45         cpu_flags_x86_aes? (
  46                 amd64? ( dev-lang/yasm )
  47                 x86? ( dev-lang/yasm )
  48         )
  49         doc? ( virtual/latex-base )
  50         test? (
  51                 ${PYTHON_DEPS}
  52                 dev-lang/tcl:0
  53                 dev-util/dejagnu
  54                 dev-util/cmocka
  55         )"
  56 RDEPEND="${DEPEND}
  57         selinux? ( sec-policy/selinux-kerberos )"
  58
  59 S=${WORKDIR}/${MY_P}/src
  60
  61 PATCHES=(
  62         "${FILESDIR}/${PN}-1.12_warn_cflags.patch"
  63         "${FILESDIR}/${PN}-config_LDFLAGS-r1.patch"
  64         "${FILESDIR}/${PN}-1.16.3-libressl-r1.patch"
  65         "${FILESDIR}/${PN}_dont_create_run.patch"
  66         "${FILESDIR}/${P}-libressl.patch"
  67 )
  68
  69 MULTILIB_CHOST_TOOLS=(
  70         /usr/bin/krb5-config
  71 )
  72
  73 src_prepare() {
  74         default
  75         # Make sure we always use the system copies.
  76         rm -rf util/{et,ss,verto}
  77         sed -i 's:^[[:space:]]*util/verto$::' configure.ac || die
  78
  79         eautoreconf
  80 }
  81
  82 src_configure() {
  83         # QA
  84         append-flags -fno-strict-aliasing
  85         append-flags -fno-strict-overflow
  86
  87         multilib-minimal_src_configure
  88 }
  89
  90 multilib_src_configure() {
  91         ECONF_SOURCE=${S} \
  92         WARN_CFLAGS="set" \
  93         econf \
  94                 $(use_with openldap ldap) \
  95                 "$(multilib_native_use_with test tcl "${EPREFIX}/usr")" \
  96                 $(use_enable nls) \
  97                 $(use_enable pkinit) \
  98                 $(use_enable threads thread-support) \
  99                 $(use_with lmdb) \
 100                 $(use_with keyutils) \
 101                 --without-hesiod \
 102                 --enable-shared \
 103                 --with-system-et \
 104                 --with-system-ss \
 105                 --enable-dns-for-realm \
 106                 --enable-kdc-lookaside-cache \
 107                 --with-system-verto \
 108                 --disable-rpath
 109 }
 110
 111 multilib_src_compile() {
 112         emake -j1
 113 }
 114
 115 multilib_src_test() {
 116         multilib_is_native_abi && emake -j1 check
 117 }
 118
 119 multilib_src_install() {
 120         emake \
 121                 DESTDIR="${D}" \
 122                 EXAMPLEDIR="${EPREFIX}/usr/share/doc/${PF}/examples" \
 123                 install
 124 }
 125
 126 multilib_src_install_all() {
 127         # default database dir
 128         keepdir /var/lib/krb5kdc
 129
 130         cd ..
 131         dodoc README
 132
 133         if use doc; then
 134                 dodoc -r doc/html
 135                 docinto pdf
 136                 dodoc doc/pdf/*.pdf
 137         fi
 138
 139         newinitd "${FILESDIR}"/mit-krb5kadmind.initd-r2 mit-krb5kadmind
 140         newinitd "${FILESDIR}"/mit-krb5kdc.initd-r2 mit-krb5kdc
 141         newinitd "${FILESDIR}"/mit-krb5kpropd.initd-r2 mit-krb5kpropd
 142         newconfd "${FILESDIR}"/mit-krb5kadmind.confd mit-krb5kadmind
 143         newconfd "${FILESDIR}"/mit-krb5kdc.confd mit-krb5kdc
 144         newconfd "${FILESDIR}"/mit-krb5kpropd.confd mit-krb5kpropd
 145
 146         systemd_newunit "${FILESDIR}"/mit-krb5kadmind.service mit-krb5kadmind.service
 147         systemd_newunit "${FILESDIR}"/mit-krb5kdc.service mit-krb5kdc.service
 148         systemd_newunit "${FILESDIR}"/mit-krb5kpropd.service mit-krb5kpropd.service
 149         systemd_newunit "${FILESDIR}"/mit-krb5kpropd_at.service "mit-krb5kpropd@.service"
 150         systemd_newunit "${FILESDIR}"/mit-krb5kpropd.socket mit-krb5kpropd.socket
 151
 152         insinto /etc
 153         newins "${ED}/usr/share/doc/${PF}/examples/krb5.conf" krb5.conf.example
 154         insinto /var/lib/krb5kdc
 155         newins "${ED}/usr/share/doc/${PF}/examples/kdc.conf" kdc.conf.example
 156
 157         if use openldap ; then
 158                 insinto /etc/openldap/schema
 159                 doins "${S}/plugins/kdb/ldap/libkdb_ldap/kerberos.schema"
 160         fi
 161
 162         if use xinetd ; then
 163                 insinto /etc/xinetd.d
 164                 newins "${FILESDIR}/kpropd.xinetd" kpropd
 165         fi
 166 }