app-crypt/kbfs/kbfs-2.8.0.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit golang-build systemd
   7
   8 DESCRIPTION="Keybase Filesystem (KBFS)"
   9 HOMEPAGE="https://keybase.io/docs/kbfs"
  10 SRC_URI="https://github.com/keybase/kbfs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 DEPEND=""
  18 RDEPEND="
  19         app-crypt/gnupg
  20         sys-fs/fuse
  21         "
  22
  23 src_unpack() {
  24         unpack "${P}.tar.gz"
  25         mkdir -vp "${S}/src/github.com/keybase" || die
  26         ln -vs "${S}" "${S}/src/github.com/keybase/kbfs" || die
  27 }
  28
  29 src_compile() {
  30         EGO_PN="github.com/keybase/kbfs/kbfsfuse" \
  31                 EGO_BUILD_FLAGS="-tags production -o ${T}/kbfsfuse" \
  32                 golang-build_src_compile
  33         EGO_PN="github.com/keybase/kbfs/kbfsgit/git-remote-keybase" \
  34                 EGO_BUILD_FLAGS="-tags production -o ${T}/git-remote-keybase" \
  35                 golang-build_src_compile
  36         EGO_PN="github.com/keybase/kbfs/redirector" \
  37                 EGO_BUILD_FLAGS="-tags production -o ${T}/keybase-redirector" \
  38                 golang-build_src_compile
  39 }
  40
  41 src_test() {
  42         EGO_PN="github.com/keybase/kbfs/kbfsfuse" \
  43                 golang-build_src_test
  44 }
  45
  46 src_install() {
  47         dobin "${T}/kbfsfuse"
  48         dobin "${T}/git-remote-keybase"
  49         dobin "${T}/keybase-redirector"
  50         systemd_douserunit "${S}/packaging/linux/systemd/kbfs.service"
  51 }