app-benchmarks/tiobench/tiobench-0.4.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Portable, robust, fully-threaded I/O benchmark program"
   9 HOMEPAGE="https://github.com/mkuoppal/tiobench"
  10 SRC_URI="https://github.com/mkuoppal/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc ppc64 x86"
  15 IUSE=""
  16
  17 RDEPEND="dev-lang/perl"
  18 DEPEND="${RDEPEND}"
  19
  20 PATCHES=(
  21         "${FILESDIR}"/${P}-gcc5.patch
  22         "${FILESDIR}"/${P}-fix-perl-shebang.patch
  23 )
  24
  25 src_prepare() {
  26         default
  27         sed -i \
  28                 -e "s:/usr/local/bin:${EPREFIX}/usr/sbin:" tiobench.pl \
  29                 || die "sed tiobench.pl failed"
  30 }
  31
  32 src_compile() {
  33         emake \
  34                 CC="$(tc-getCC)" \
  35                 LINK="$(tc-getCC)" \
  36                 DEFINES="-DLARGEFILES" \
  37                 CFLAGS="${CFLAGS}" \
  38                 LDFLAGS="${LDFLAGS}"
  39 }
  40
  41 src_install() {
  42         dosbin tiotest tiobench.pl scripts/tiosum.pl
  43         einstalldocs
  44 }