app-benchmarks/sysbench/sysbench-1.0.17-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools pax-utils
   7
   8 DESCRIPTION="System performance benchmark"
   9 HOMEPAGE="https://github.com/akopytov/sysbench"
  10 SRC_URI="https://github.com/akopytov/sysbench/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="aio mysql postgres test"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="aio? ( dev-libs/libaio )
  19         mysql? ( dev-db/mysql-connector-c:= )
  20         postgres? ( dev-db/postgresql:= )
  21         dev-lang/luajit:="
  22 DEPEND="${RDEPEND}
  23         dev-libs/concurrencykit
  24         dev-libs/libxslt
  25         sys-devel/libtool
  26         virtual/pkgconfig
  27         test? ( dev-util/cram )"
  28
  29 src_prepare() {
  30         default
  31
  32         # remove bundled libs
  33         rm -r third_party/luajit/luajit third_party/concurrency_kit/ck third_party/cram || die
  34
  35         eautoreconf
  36 }
  37
  38 src_configure() {
  39         local myeconfargs=(
  40                 $(use_enable aio)
  41                 $(use_with mysql)
  42                 $(use_with postgres pgsql)
  43                 --without-attachsql
  44                 --without-drizzle
  45                 --without-oracle
  46                 --with-system-luajit
  47                 --with-system-ck
  48         )
  49
  50         econf "${myeconfargs[@]}"
  51 }
  52
  53 src_test() {
  54         emake check test
  55 }
  56
  57 src_install() {
  58         default
  59
  60         pax-mark m "${ED}"/usr/bin/${PN}
  61 }