app-benchmarks/sysbench/sysbench-1.0.16-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools pax-utils
   7
   8 DESCRIPTION="System performance benchmark"
   9 HOMEPAGE="https://github.com/akopytov/sysbench"
  10 SRC_URI="https://github.com/akopytov/sysbench/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="aio mysql postgres test"
  16
  17 RDEPEND="aio? ( dev-libs/libaio )
  18         mysql? ( dev-db/mysql-connector-c:= )
  19         postgres? ( dev-db/postgresql:= )
  20         dev-lang/luajit:="
  21 DEPEND="${RDEPEND}
  22         dev-libs/concurrencykit
  23         dev-libs/libxslt
  24         sys-devel/libtool
  25         virtual/pkgconfig
  26         test? ( dev-util/cram )"
  27
  28 src_prepare() {
  29         default
  30
  31         # remove bundled libs
  32         rm -r third_party/luajit/luajit third_party/concurrency_kit/ck third_party/cram || die
  33
  34         eautoreconf
  35 }
  36
  37 src_configure() {
  38         local myeconfargs=(
  39                 $(use_enable aio)
  40                 $(use_with mysql)
  41                 $(use_with postgres pgsql)
  42                 --without-attachsql
  43                 --without-drizzle
  44                 --without-oracle
  45                 --with-system-luajit
  46                 --with-system-ck
  47         )
  48
  49         econf "${myeconfargs[@]}"
  50 }
  51
  52 src_test() {
  53         emake check test
  54 }
  55
  56 src_install() {
  57         default
  58
  59         pax-mark m "${ED}"/usr/bin/${PN}
  60 }