app-backup/snapper/snapper-9999.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 EGIT_REPO_URI="git://github.com/openSUSE/snapper.git"
   8 AUTOTOOLS_AUTORECONF=1
   9 AUTOTOOLS_IN_SOURCE_BUILD=1
  10 inherit eutils autotools-utils git-r3
  11
  12 DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
  13 HOMEPAGE="http://snapper.io/"
  14 SRC_URI=""
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="+btrfs ext4 lvm pam xattr"
  20
  21 RDEPEND="dev-libs/boost[threads]
  22         dev-libs/libxml2
  23         dev-libs/icu:=
  24         sys-apps/acl
  25         sys-apps/dbus
  26         sys-apps/util-linux
  27         sys-libs/zlib
  28         virtual/libintl
  29         btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
  30         ext4? ( sys-fs/e2fsprogs )
  31         lvm? ( sys-fs/lvm2 )
  32         pam? ( sys-libs/pam )
  33         xattr? ( sys-apps/attr )"
  34
  35 DEPEND="${RDEPEND}
  36         sys-devel/gettext
  37         virtual/pkgconfig"
  38
  39 DOCS=( AUTHORS README package/snapper.changes )
  40
  41 PATCHES=( "${FILESDIR}"/cron-confd.patch )
  42
  43 src_configure() {
  44         local myeconfargs=(
  45                 --with-conf="/etc/conf.d"
  46                 --docdir="/usr/share/doc/${PF}"
  47                 --disable-zypp
  48                 $(use_enable btrfs)
  49                 $(use_enable ext4)
  50                 $(use_enable lvm)
  51                 $(use_enable pam)
  52                 $(use_enable xattr xattrs)
  53         )
  54         autotools-utils_src_configure
  55 }
  56
  57 src_install() {
  58         autotools-utils_src_install
  59         # Existing configuration file required to function
  60         newconfd data/sysconfig.snapper snapper
  61 }
  62
  63 pkg_postinst() {
  64         elog "In order to use Snapper, you need to set up"
  65         elog "at least one config first. To do this, run:"
  66         elog "snapper create-config <subvolume>"
  67         elog "For more information, see man (8) snapper or"
  68         elog "http://snapper.io/documentation.html"
  69 }