app-backup/snapper/snapper-0.2.8-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils
   8
   9 DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
  10 HOMEPAGE="http://snapper.io/"
  11 SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="+btrfs ext4 lvm pam xattr"
  17
  18 RDEPEND="dev-libs/boost:=[threads]
  19         dev-libs/libxml2
  20         dev-libs/icu:=
  21         sys-apps/acl
  22         sys-apps/dbus
  23         sys-apps/util-linux
  24         sys-libs/zlib
  25         virtual/libintl
  26         btrfs? ( >=sys-fs/btrfs-progs-3.17.1 )
  27         ext4? ( sys-fs/e2fsprogs )
  28         lvm? ( sys-fs/lvm2 )
  29         pam? ( sys-libs/pam )
  30         xattr? ( sys-apps/attr )"
  31
  32 DEPEND="${RDEPEND}
  33         sys-devel/gettext
  34         virtual/pkgconfig"
  35
  36 REQUIRED_USE="|| ( btrfs ext4 lvm )"
  37
  38 DOCS=( AUTHORS README )
  39
  40 src_prepare() {
  41         epatch "${FILESDIR}"/cron-confd.patch
  42 }
  43
  44 src_configure() {
  45         local myeconfargs=(
  46                 --with-conf="/etc/conf.d"
  47                 --docdir="/usr/share/doc/${PF}"
  48                 --disable-zypp
  49                 --enable-rollback
  50                 $(use_enable btrfs)
  51                 $(use_enable ext4)
  52                 $(use_enable lvm)
  53                 $(use_enable pam)
  54                 $(use_enable xattr xattrs)
  55         )
  56
  57         econf "${myeconfargs[@]}"
  58 }
  59
  60 src_install() {
  61         default
  62         # Existing configuration file required to function
  63         newconfd data/sysconfig.snapper snapper
  64         prune_libtool_files
  65 }
  66
  67 pkg_postinst() {
  68         elog "In order to use Snapper, you need to set up"
  69         elog "at least one config first. To do this, run:"
  70         elog "snapper create-config <subvolume>"
  71         elog "For more information, see man (8) snapper or"
  72         elog "http://snapper.io/documentation.html"
  73 }