app-backup/rear/rear-1.17.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit eutils
   7
   8 DESCRIPTION="A setup-and-forget Linux bare metal disaster recovery solution"
   9 HOMEPAGE="http://relax-and-recover.org/"
  10 MY_PV=${PV%.*}
  11 SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${MY_PV}/${PV}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16
  17 IUSE="libressl udev"
  18
  19 RDEPEND="
  20         !libressl? ( dev-libs/openssl:0= )
  21         libressl? ( dev-libs/libressl:0= )
  22         net-dialup/mingetty
  23         net-fs/nfs-utils
  24         sys-apps/gawk
  25         sys-apps/iproute2
  26         sys-apps/lsb-release
  27         sys-apps/util-linux
  28         sys-block/parted
  29         sys-boot/syslinux
  30         virtual/cdrtools
  31         udev? ( virtual/udev )
  32 "
  33
  34 src_compile () { :; }
  35
  36 src_install () {
  37         # Deploy udev USB rule and udev will autostart ReaR workflows in case a USB
  38         # drive with the label 'REAR_000' is connected, which in turn is the
  39         # default label when running the `rear format` command.
  40         if use udev ; then
  41                 insinto /lib/udev/rules.d
  42                 doins etc/udev/rules.d/62-${PN}-usb.rules
  43         fi
  44
  45         # Copy main script-file and documentation.
  46         dosbin usr/sbin/${PN}
  47         doman doc/${PN}.8
  48         dodoc README
  49
  50         # Copy configurations files.
  51         insinto /etc
  52         doins -r etc/${PN}/
  53
  54         insinto /usr/share/
  55         doins -r usr/share/${PN}/
  56 }