app-backup/deja-dup/deja-dup-34.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GCONF_DEBUG="no"
   6 VALA_MAX_API_VERSION="0.42"
   7
   8 inherit cmake-utils eutils gnome2 vala
   9
  10 DESCRIPTION="Simple backup tool using duplicity back-end"
  11 HOMEPAGE="https://launchpad.net/deja-dup/"
  12 SRC_URI="https://launchpad.net/${PN}/34/${PV}/+download/${P}.tar.xz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="nautilus test"
  18 RESTRICT="test" # bug#????
  19
  20 COMMON_DEPEND="
  21         app-admin/packagekit-base
  22         app-crypt/libsecret[vala]
  23         >=dev-libs/glib-2.34:2[dbus]
  24         >=dev-libs/libpeas-1.0
  25         >=x11-libs/gtk+-3.10:3
  26         >=x11-libs/libnotify-0.7
  27
  28         >=app-backup/duplicity-0.6.23
  29         dev-libs/dbus-glib
  30
  31         nautilus? ( gnome-base/nautilus )
  32 "
  33 RDEPEND="${COMMON_DEPEND}
  34         gnome-base/dconf
  35         gnome-base/gvfs[fuse]
  36 "
  37 DEPEND="${COMMON_DEPEND}
  38         $(vala_depend)
  39         app-text/yelp-tools
  40         dev-perl/Locale-gettext
  41         virtual/pkgconfig
  42         dev-util/intltool
  43         sys-devel/gettext
  44 "
  45
  46 src_prepare() {
  47         sed \
  48                 -e '/RPATH/s:PKG_LIBEXECDIR:PKG_LIBDIR:g' \
  49                 -i CMakeLists.txt || die
  50         vala_src_prepare
  51         gnome2_src_prepare
  52         cmake-utils_src_prepare
  53 }
  54
  55 src_configure() {
  56         local mycmakeargs=(
  57                 -DVALA_EXECUTABLE="${VALAC}"
  58                 -DENABLE_CCPANEL=OFF
  59                 -DENABLE_PK=OFF
  60                 -DENABLE_UNITY=OFF
  61                 -DENABLE_UNITY_CCPANEL=OFF
  62                 -DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc
  63                 -DENABLE_NAUTILUS="$(usex nautilus)"
  64                 -DENABLE_TESTING="$(usex test)"
  65         )
  66         cmake-utils_src_configure
  67 }
  68
  69 src_compile() {
  70         cmake-utils_src_compile
  71 }
  72
  73 src_install() {
  74         cmake-utils_src_install
  75 }