app-backup/dar/dar-2.6.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit flag-o-matic
   6
   7 DESCRIPTION="A full featured backup tool, aimed for disks"
   8 HOMEPAGE="http://dar.linux.free.fr/"
   9 SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
  14 IUSE="curl dar32 dar64 doc gcrypt gpg lzo nls static static-libs xattr"
  15
  16 RESTRICT="test" # need to be run as root
  17
  18 RDEPEND=">=sys-libs/zlib-1.2.3:=
  19         !static? (
  20                 app-arch/bzip2:=
  21                 app-arch/xz-utils:=
  22                 sys-libs/libcap
  23                 curl? ( net-misc/curl )
  24                 gcrypt? ( dev-libs/libgcrypt:0= )
  25                 gpg? ( app-crypt/gpgme )
  26                 lzo? ( dev-libs/lzo:= )
  27                 xattr? ( sys-apps/attr:= )
  28         )"
  29
  30 DEPEND="${RDEPEND}
  31         static? (
  32                 app-arch/bzip2[static-libs]
  33                 app-arch/xz-utils[static-libs]
  34                 sys-libs/libcap[static-libs]
  35                 sys-libs/zlib[static-libs]
  36                 curl? ( net-misc/curl[static-libs] )
  37                 gcrypt? ( dev-libs/libgcrypt:0=[static-libs] )
  38                 gpg? (
  39                         app-crypt/gpgme[static-libs]
  40                         dev-libs/libassuan[static-libs]
  41                         dev-libs/libgpg-error[static-libs]
  42                 )
  43                 lzo? ( dev-libs/lzo[static-libs] )
  44                 xattr? ( sys-apps/attr[static-libs] )
  45         )
  46 "
  47 BDEPEND="
  48         nls? (
  49                 sys-devel/gettext
  50                 virtual/libintl
  51         )
  52         doc? ( app-doc/doxygen )
  53 "
  54
  55 REQUIRED_USE="?? ( dar32 dar64 )
  56                 gpg? ( gcrypt )"
  57
  58 #PATCHES=(
  59 #)
  60
  61 src_configure() {
  62         # configure.ac is totally funked up regarding the AC_ARG_ENABLE
  63         # logic.
  64         # For example "--enable-dar-static" causes configure to DISABLE
  65         # static builds of dar.
  66         # Do _not_ use $(use_enable) until you have verified that the
  67         # logic has been fixed by upstream.
  68         local myconf=(
  69                 --disable-upx
  70                 $(usex curl '' --disable-libcurl-linking)
  71                 $(usex dar32 --enable-mode=32 '')
  72                 $(usex dar64 --enable-mode=64 '')
  73                 $(usex doc '' --disable-build-html)
  74                 #$(usex examples --enable-examples '')
  75                 $(usex gcrypt '' --disable-libgcrypt-linking)
  76                 $(usex gpg '' --disable-gpgme-linking)
  77                 $(usex lzo '' --disable-liblzo2-linking)
  78                 $(usex nls '' --disable-nls)
  79                 #$(usex rsync '' --disable-librsync-linking)
  80                 $(usex xattr '' --disable-ea-support)
  81         )
  82
  83         # Bug 103741
  84         filter-flags -fomit-frame-pointer
  85
  86         if ! use static ; then
  87                 myconf+=( --disable-dar-static )
  88                 if ! use static-libs ; then
  89                         myconf+=( --disable-static )
  90                 fi
  91         fi
  92
  93         econf ${myconf[@]}
  94 }
  95
  96 src_install() {
  97         emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
  98
  99         local DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
 100         einstalldocs
 101
 102         find "${ED}" -name '*.la' -delete || die
 103         if ! use static-libs ; then
 104                 find "${ED}" -name '*.a' -delete || die
 105         fi
 106 }