app-backup/dar/dar-2.5.4.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 inherit confutils flag-o-matic
   7
   8 DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
   9 HOMEPAGE="http://dar.linux.free.fr/"
  10 SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
  15 IUSE="acl dar32 dar64 doc gcrypt gpgme lzo nls static static-libs"
  16
  17 RESTRICT="test" # need to be run as root
  18
  19 RDEPEND=">=sys-libs/zlib-1.2.3:=
  20         !static? ( app-arch/bzip2:=
  21                     app-arch/xz-utils:= )
  22         acl? ( !static? ( sys-apps/attr:= ) )
  23         gcrypt? ( dev-libs/libgcrypt:0= )
  24         gpgme? ( app-crypt/gpgme )
  25         lzo? ( !static? ( dev-libs/lzo:= ) )
  26         nls? ( virtual/libintl )"
  27
  28 DEPEND="${RDEPEND}
  29         static? ( app-arch/bzip2[static-libs]
  30                     app-arch/xz-utils[static-libs]
  31                     sys-libs/zlib[static-libs] )
  32         acl? ( static? ( sys-apps/attr[static-libs] ) )
  33         lzo? ( static? ( dev-libs/lzo[static-libs] ) )
  34         nls? ( sys-devel/gettext )
  35         doc? ( app-doc/doxygen )"
  36
  37 REQUIRED_USE="?? ( dar32 dar64 )
  38                 gpgme? ( gcrypt )"
  39
  40 DOCS="AUTHORS ChangeLog NEWS README THANKS TODO"
  41
  42 #PATCHES=(
  43 #)
  44
  45 src_configure() {
  46         local myconf=( --disable-upx )
  47
  48         # Bug 103741
  49         filter-flags -fomit-frame-pointer
  50
  51         use acl || myconf+=( --disable-ea-support )
  52         use dar32 && myconf+=( --enable-mode=32 )
  53         use dar64 && myconf+=( --enable-mode=64 )
  54         use doc || myconf+=( --disable-build-html )
  55         # use examples && myconf+=( --enable-examples )
  56         use gcrypt || myconf+=( --disable-libgcrypt-linking )
  57         use gpgme || myconf+=( --disable-gpgme-linking )
  58         use lzo || myconf+=( --disable-liblzo2-linking )
  59         use nls || myconf=( --disable-nls )
  60         if ! use static ; then
  61                 myconf+=( --disable-dar-static )
  62                 if ! use static-libs ; then
  63                         myconf+=( --disable-static )
  64                 fi
  65         fi
  66
  67         econf ${myconf[@]}
  68 }
  69
  70 src_install() {
  71         emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
  72
  73         einstalldocs
  74
  75         if ! use static-libs ; then
  76                 prune_libtool_files --all
  77         fi
  78 }