app-backup/dar/dar-2.4.20.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 inherit flag-o-matic
   7
   8 DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
   9 HOMEPAGE="http://dar.linux.free.fr/"
  10 SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~ppc ~sparc ~x86 ~amd64-linux"
  15 IUSE="acl dar32 dar64 doc gcrypt lzo nls static static-libs"
  16
  17 RESTRICT="test" # need to be run as root
  18
  19 RDEPEND=">=sys-libs/zlib-1.2.3:=
  20         !static? ( app-arch/bzip2:= )
  21         acl? ( !static? ( sys-apps/attr:= ) )
  22         gcrypt? ( dev-libs/libgcrypt:0= )
  23         lzo? ( !static? ( dev-libs/lzo:= ) )
  24         nls? ( virtual/libintl )"
  25 DEPEND="${RDEPEND}
  26         static? ( app-arch/bzip2[static-libs] )
  27         static? ( sys-libs/zlib[static-libs] )
  28         acl? ( static? ( sys-apps/attr[static-libs] ) )
  29         lzo? ( static? ( dev-libs/lzo[static-libs] ) )
  30         nls? ( sys-devel/gettext )
  31         doc? ( app-doc/doxygen )"
  32
  33 REQUIRED_USE="?? ( dar32 dar64 )"
  34
  35 DOCS="AUTHORS ChangeLog NEWS README THANKS TODO"
  36
  37 src_configure() {
  38         local myconf="--disable-upx"
  39
  40         # Bug 103741
  41         filter-flags -fomit-frame-pointer
  42
  43         use acl || myconf="${myconf} --disable-ea-support"
  44         use dar32 && myconf="${myconf} --enable-mode=32"
  45         use dar64 && myconf="${myconf} --enable-mode=64"
  46         use doc || myconf="${myconf} --disable-build-html"
  47         # use examples && myconf="${myconf} --enable-examples"
  48         use gcrypt || myconf="${myconf} --disable-libgcrypt-linking"
  49         use lzo || myconf="${myconf} --disable-liblzo2-linking"
  50         use nls || myconf="${myconf} --disable-nls"
  51         if ! use static ; then
  52                 myconf="${myconf} --disable-dar-static"
  53                 if ! use static-libs ; then
  54                         myconf="${myconf} --disable-static"
  55                 fi
  56         fi
  57
  58         econf ${myconf}
  59 }
  60
  61 src_install() {
  62         emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
  63
  64         einstalldocs
  65
  66         if ! use static-libs ; then
  67                 prune_libtool_files --all
  68         fi
  69 }