app-backup/buttersink/buttersink-0.6.8.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="rsync-like utility for btrfs snapshots"
  10 HOMEPAGE="https://github.com/AmesCornish/buttersink"
  11
  12 LICENSE="GPL-3"
  13 SLOT=0
  14
  15 # local tests would require root and cause sandbox issues with btrfs subvolume
  16 # operations, and network tests would require an SSH server with root login to
  17 # test the SSH backend, or remote S3 for that backend
  18 RESTRICT="test"
  19
  20 if [[ ${PV} == 9999 ]] ; then
  21         inherit git-r3
  22         KEYWORDS=""
  23         EGIT_REPO_URI="https://github.com/AmesCornish/buttersink"
  24         SRC_URI=""
  25 else
  26         KEYWORDS="~amd64 ~x86"
  27         SRC_URI="https://github.com/AmesCornish/buttersink/archive/${PV}.tar.gz -> ${P}.tar.gz"
  28 fi
  29
  30 RDEPEND="${PYTHON_DEPS}
  31         dev-python/boto[${PYTHON_USEDEP}]
  32         dev-python/crcmod[${PYTHON_USEDEP}]
  33         dev-python/psutil[${PYTHON_USEDEP}]
  34         sys-fs/btrfs-progs"
  35 DEPEND="${RDEPEND}"
  36
  37 python_prepare_all() {
  38         if [[ ${PV} == 9999 ]] ; then
  39                 emake makestamps buttersink/version.py
  40         else
  41                 mkdir makestamps || die
  42                 echo "version = \"${PV}\"" > buttersink/version.py || die
  43         fi
  44         distutils-r1_python_prepare_all
  45 }