app-arch/zstd/zstd-1.4.4-r4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic multilib-minimal toolchain-funcs
   7
   8 DESCRIPTION="zstd fast compression library"
   9 HOMEPAGE="https://facebook.github.io/zstd/"
  10 SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="|| ( BSD GPL-2 )"
  13 SLOT="0/1"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="lz4 static-libs +threads"
  16
  17 RDEPEND="app-arch/xz-utils
  18         lz4? ( app-arch/lz4 )"
  19 DEPEND="${RDEPEND}"
  20
  21 PATCHES=(
  22         "${FILESDIR}/${P}-pkgconfig_libdir.patch" #700780
  23         "${FILESDIR}/${P}-make43.patch" #708110
  24 )
  25
  26 src_prepare() {
  27         default
  28         multilib_copy_sources
  29
  30         # Workaround #713940 / https://github.com/facebook/zstd/issues/2045
  31         # where upstream build system does not add -pthread for Makefile-based
  32         # build system.
  33         use threads && append-flags $(test-flags-CCLD -pthread)
  34 }
  35
  36 mymake() {
  37         emake \
  38                 CC="$(tc-getCC)" \
  39                 CXX="$(tc-getCXX)" \
  40                 AR="$(tc-getAR)" \
  41                 PREFIX="${EPREFIX}/usr" \
  42                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
  43                 "${@}"
  44 }
  45
  46 multilib_src_compile() {
  47         local libzstd_targets=( libzstd{,.a}$(usex threads '-mt' '') )
  48
  49         mymake -C lib ${libzstd_targets[@]} libzstd.pc
  50
  51         if multilib_is_native_abi ; then
  52                 mymake HAVE_LZ4="$(usex lz4 1 0)" zstd
  53
  54                 mymake -C contrib/pzstd
  55         fi
  56 }
  57
  58 multilib_src_install() {
  59         mymake -C lib DESTDIR="${D}" install
  60
  61         if multilib_is_native_abi ; then
  62                 mymake -C programs DESTDIR="${D}" install
  63
  64                 mymake -C contrib/pzstd DESTDIR="${D}" install
  65         fi
  66 }
  67
  68 multilib_src_install_all() {
  69         einstalldocs
  70
  71         if ! use static-libs; then
  72                 find "${ED}" -name "*.a" -delete || die
  73         fi
  74 }