app-arch/zstd/zstd-1.2.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="zstd fast compression library"
   9 HOMEPAGE="https://facebook.github.io/zstd/"
  10 SRC_URI="https://github.com/facebook/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
  15 IUSE="static-libs"
  16
  17 src_compile() {
  18         emake \
  19                 CC="$(tc-getCC)" \
  20                 AR="$(tc-getAR)" \
  21                 PREFIX="${EPREFIX}/usr" \
  22                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" zstd
  23
  24         emake -C lib \
  25                 CC="$(tc-getCC)" \
  26                 AR="$(tc-getAR)" \
  27                 PREFIX="${EPREFIX}/usr" \
  28                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" libzstd
  29 }
  30
  31 src_install() {
  32         emake \
  33                 DESTDIR="${D}" \
  34                 PREFIX="${EPREFIX}/usr" \
  35                 LIBDIR="${EPREFIX}/usr/$(get_libdir)" install
  36         einstalldocs
  37
  38         if ! use static-libs; then
  39                 rm "${ED%/}"/usr/$(get_libdir)/libzstd.a || die
  40         fi
  41 }