app-arch/zip/zip-3.0-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="2"
   6 inherit toolchain-funcs eutils flag-o-matic
   7
   8 MY_P="${PN}${PV//.}"
   9 DESCRIPTION="Info ZIP (encryption support)"
  10 HOMEPAGE="http://www.info-zip.org/"
  11 SRC_URI="mirror://sourceforge/infozip/${MY_P}.zip"
  12
  13 LICENSE="Info-ZIP"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~arm-linux"
  16 IUSE="bzip2 crypt natspec unicode"
  17
  18 RDEPEND="bzip2? ( app-arch/bzip2 )
  19         natspec? ( dev-libs/libnatspec )"
  20 DEPEND="${RDEPEND}
  21         app-arch/unzip"
  22
  23 S=${WORKDIR}/${MY_P}
  24
  25 src_prepare() {
  26         epatch "${FILESDIR}"/${PN}-3.0-no-crypt.patch #238398
  27         epatch "${FILESDIR}"/${PN}-3.0-pic.patch
  28         epatch "${FILESDIR}"/${PN}-3.0-exec-stack.patch
  29         epatch "${FILESDIR}"/${PN}-3.0-build.patch
  30         use natspec && epatch "${FILESDIR}"/${PN}-3.0-natspec.patch #275244
  31 }
  32
  33 src_compile() {
  34         use bzip2 || append-flags -DNO_BZIP2_SUPPORT
  35         use crypt || append-flags -DNO_CRYPT
  36         use unicode || append-flags -DNO_UNICODE_SUPPORT
  37         emake \
  38                 CC="$(tc-getCC)" \
  39                 LOCAL_ZIP="${CFLAGS} ${CPPFLAGS}" \
  40                 -f unix/Makefile generic \
  41                 || die
  42 }
  43
  44 src_install() {
  45         dobin zip zipnote zipsplit || die
  46         doman man/zip{,note,split}.1
  47         if use crypt ; then
  48                 dobin zipcloak || die
  49                 doman man/zipcloak.1
  50         fi
  51         dodoc BUGS CHANGES README* TODO WHATSNEW WHERE proginfo/*.txt
  52 }