app-arch/xarchiver/xarchiver-0.5.4.14.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools gnome2-utils xdg-utils
   7
   8 DESCRIPTION="A GTK+ archive manager that can be used with Thunar"
   9 HOMEPAGE="https://github.com/ib/xarchiver"
  10 SRC_URI="https://github.com/ib/xarchiver/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
  15 IUSE="doc"
  16
  17 # older pigz versions have incompatible command-line processing
  18 # https://bugs.gentoo.org/661464
  19 RDEPEND=">=dev-libs/glib-2:=
  20         x11-libs/gtk+:3=
  21         !!<app-arch/pigz-2.4[symlink]"
  22 DEPEND="${RDEPEND}
  23         dev-util/intltool
  24         sys-devel/gettext
  25         virtual/pkgconfig
  26         doc? (
  27                 app-text/docbook-xml-dtd
  28                 app-text/docbook-xsl-stylesheets
  29                 dev-libs/libxml2
  30                 dev-libs/libxslt
  31         )"
  32
  33 src_prepare() {
  34         sed -e '/COPYING/d' -e '/NEWS/d' -i doc/Makefile.am || die
  35         default
  36         eautoreconf
  37 }
  38
  39 src_configure() {
  40         local myconf=(
  41                 $(use_enable doc)
  42         )
  43         econf "${myconf[@]}"
  44 }
  45
  46 pkg_postinst() {
  47         xdg_desktop_database_update
  48         gnome2_icon_cache_update
  49
  50         elog "You need external programs for some formats, including:"
  51         elog "7zip - app-arch/p7zip"
  52         elog "arj - app-arch/unarj app-arch/arj"
  53         elog "lha - app-arch/lha"
  54         elog "lzop - app-arch/lzop"
  55         elog "rar - app-arch/unrar app-arch/rar"
  56         elog "zip - app-arch/unzip app-arch/zip"
  57 }
  58
  59 pkg_postrm() {
  60         xdg_desktop_database_update
  61         gnome2_icon_cache_update
  62 }