app-arch/pixz/pixz-1.0.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit toolchain-funcs flag-o-matic autotools
   8
   9 DESCRIPTION="Parallel Indexed XZ compressor"
  10 HOMEPAGE="https://github.com/vasi/pixz"
  11 LICENSE="BSD-2"
  12 SLOT="0"
  13 IUSE="static"
  14
  15 LIB_DEPEND=">=app-arch/libarchive-2.8:=[static-libs(+)]
  16         >=app-arch/xz-utils-5[static-libs(+)]"
  17 RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
  18 DEPEND="${RDEPEND}
  19         static? ( ${LIB_DEPEND} )
  20         app-text/asciidoc"
  21
  22 if [[ ${PV} == "9999" ]] ; then
  23         EGIT_REPO_URI="https://github.com/vasi/${PN}.git"
  24         inherit git-r3
  25         KEYWORDS=""
  26 else
  27         SRC_URI="https://github.com/vasi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  28         KEYWORDS="~amd64 ~arm ~x86"
  29 fi
  30
  31 src_prepare() {
  32         eautoreconf
  33 }
  34
  35 src_configure() {
  36         use static && append-ldflags -static
  37         append-flags -std=gnu99
  38         econf
  39 }
  40
  41 src_compile() {
  42         emake CC="$(tc-getCC)" OPT=""
  43 }
  44
  45 src_install() {
  46         dobin src/pixz
  47         doman src/pixz.1
  48         dodoc README.md TODO
  49 }