app-arch/lz4/lz4-0_p106-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit cmake-utils multilib
   8
   9 CMAKE_USE_DIR="${S}/cmake"
  10
  11 if [ ${PV} == "9999" ] ; then
  12         inherit subversion
  13         ESVN_REPO_URI="http://lz4.googlecode.com/svn/trunk/"
  14         ESVN_PROJECT="lz4-read-only"
  15 else
  16         SRC_URI="https://dev.gentoo.org/~ryao/dist/${P}.tar.xz"
  17         KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-linux ~x86-linux"
  18 fi
  19
  20 DESCRIPTION="Extremely Fast Compression algorithm"
  21 HOMEPAGE="https://code.google.com/p/lz4/"
  22
  23 LICENSE="BSD-2"
  24 SLOT="0"
  25 IUSE=""
  26
  27 DEPEND=""
  28 RDEPEND="${DEPEND}"
  29
  30 src_prepare() {
  31         if [ ${PV} == "9999" ]
  32         then
  33                 subversion_src_prepare
  34         else
  35                 epatch "${FILESDIR}/${P}-install-to-bindir.patch"
  36                 epatch "${FILESDIR}/${P}-cflags.patch"
  37         fi
  38         cmake-utils_src_prepare
  39 }
  40
  41 src_configure() {
  42         local mycmakeargs=(-DBUILD_SHARED_LIBS=ON)
  43         cmake-utils_src_configure
  44 }
  45
  46 src_install() {
  47         dodir /usr
  48         dodir "/usr/$(get_libdir)"
  49         ln -s "$(get_libdir)" "${ED}usr/lib" || \
  50                 die "Cannot create temporary symlink from usr/lib to usr/$(get_libdir)"
  51
  52         cmake-utils_src_install
  53
  54         rm "${ED}usr/lib"
  55
  56         if [ -f "${ED}usr/bin/lz4c64" ]
  57         then
  58                 dosym lz4c64 /usr/bin/lz4c
  59         else
  60                 dosym lz4c32 /usr/bin/lz4c
  61         fi
  62 }