app-arch/dump/dump-0.4.46-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P="${PN}-$(ver_rs 2 b)"
   7 S=${WORKDIR}/${MY_P}
   8 DESCRIPTION="Dump/restore ext2fs backup utilities"
   9 HOMEPAGE="http://dump.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/dump/${MY_P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 ~sparc x86"
  15 # We keep uuid USE flag default dsiabled for this version. Don't forget
  16 # to default enable it for later versions as this is the upstream default.
  17 IUSE="bzip2 debug ermt libressl lzo readline selinux sqlite ssl static test uuid zlib"
  18 REQUIRED_USE="
  19         ermt? ( ssl )
  20         ssl? ( zlib )
  21         test? ( sqlite? ( uuid ) )
  22 "
  23
  24 RDEPEND=">=sys-fs/e2fsprogs-1.27:=
  25         >=sys-libs/e2fsprogs-libs-1.27:=
  26         sys-apps/util-linux
  27         bzip2? ( >=app-arch/bzip2-1.0.2:= )
  28         zlib? ( >=sys-libs/zlib-1.1.4:= )
  29         lzo? ( dev-libs/lzo:2= )
  30         sqlite? ( dev-db/sqlite:3= )
  31         ermt? (
  32                 !libressl? ( dev-libs/openssl:0= )
  33                 libressl? ( dev-libs/libressl:0= )
  34         )
  35         ssl? (
  36                 !libressl? ( dev-libs/openssl:0= )
  37                 libressl? ( dev-libs/libressl:0= )
  38         )
  39         readline? (
  40                 sys-libs/readline:0=
  41                 sys-libs/ncurses:=
  42                 static? ( sys-libs/ncurses:=[static-libs] )
  43         )"
  44 DEPEND="${RDEPEND}
  45         virtual/os-headers"
  46 BDEPEND="
  47         virtual/pkgconfig
  48 "
  49
  50 PATCHES=(
  51         "${FILESDIR}"/${P}-openssl11.patch
  52 )
  53
  54 src_configure() {
  55         local myeconfargs=(
  56                 --with-dumpdatespath=/etc/dumpdates
  57                 --with-rmtpath='$(sbindir)/rmt'
  58                 --enable-blkid
  59                 $(use_enable bzip2)
  60                 $(use_enable debug)
  61                 $(use_enable ermt)
  62                 $(use_enable lzo)
  63                 $(use_enable readline)
  64                 $(use_enable selinux)
  65                 $(use_enable sqlite)
  66                 $(use_enable ssl)
  67                 $(use_enable static static-progs)
  68                 $(use_enable uuid)
  69                 $(use_enable zlib)
  70         )
  71         econf "${myeconfargs[@]}"
  72 }
  73
  74 src_install() {
  75         default
  76         mv "${ED}"/usr/sbin/{,dump-}rmt || die
  77         mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
  78         use ermt && newsbin rmt/ermt dump-ermt
  79
  80         dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
  81         dodoc -r examples
  82 }
  83
  84 pkg_postinst() {
  85         if [[ -z ${REPLACING_VERSIONS} ]] ; then
  86                 ewarn "app-arch/dump installs 'rmt' as 'dump-rmt'."
  87                 ewarn "This is to avoid conflicts with app-arch/tar 'rmt'."
  88         fi
  89 }