app-antivirus/clamtk/clamtk-6.02-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit desktop perl-functions python-single-r1 xdg-utils
   9
  10 MY_PV_KDE="0.18"
  11 MY_PV_NAUTILUS="0.03"
  12 MY_PV_NEMO="0.04"
  13 MY_PV_THUNAR="0.06"
  14
  15 DESCRIPTION="A graphical front-end for ClamAV"
  16 HOMEPAGE="https://gitlab.com/dave_m/clamtk/wikis/Home"
  17 SRC_URI="
  18         https://bitbucket.org/davem_/${PN}-gtk3/downloads/${P}.tar.xz
  19         kde? ( https://bitbucket.org/davem_/${PN}-kde/downloads/${PN}-kde-${MY_PV_KDE}.tar.xz )
  20         nautilus? ( https://bitbucket.org/davem_/${PN}-gnome/downloads/${PN}-gnome-${MY_PV_NAUTILUS}.tar.xz )
  21         nemo? ( https://bitbucket.org/davem_/nemo-sendto-${PN}/downloads/nemo-sendto-${PN}-${MY_PV_NEMO}.tar.xz )
  22         thunar? ( https://bitbucket.org/davem_/thunar-sendto-${PN}/downloads/thunar-sendto-${PN}-${MY_PV_THUNAR}.tar.xz )
  23 "
  24
  25 LICENSE="|| ( Artistic GPL-1+ )"
  26 SLOT="0"
  27 KEYWORDS="amd64 x86"
  28 IUSE="kde nautilus nemo +nls thunar"
  29 REQUIRED_USE="nautilus? ( ${PYTHON_REQUIRED_USE} )"
  30
  31 RDEPEND="
  32         app-antivirus/clamav
  33         dev-perl/File-chdir
  34         dev-perl/Gtk3
  35         dev-perl/JSON
  36         dev-perl/LWP-Protocol-https
  37         dev-perl/LWP-UserAgent-Cached
  38         dev-perl/Locale-gettext
  39         dev-perl/Text-CSV
  40         dev-perl/glib-perl
  41         dev-perl/libwww-perl
  42         virtual/perl-Digest-MD5
  43         virtual/perl-Digest-SHA
  44         virtual/perl-Encode
  45         virtual/perl-MIME-Base64
  46         virtual/perl-Time-Piece
  47         x11-themes/faenza-icon-theme
  48         nautilus? (
  49                 ${PYTHON_DEPS}
  50                 dev-python/nautilus-python[${PYTHON_SINGLE_USEDEP}]
  51         )
  52 "
  53
  54 BDEPEND="nls? ( sys-devel/gettext )"
  55
  56 DOCS=( "CHANGES" "credits.md" "DISCLAIMER" "README.md" )
  57
  58 PATCHES=( "$FILESDIR"/"${PN}"-6.00-change_icon_path.patch )
  59
  60 pkg_setup() {
  61         use nautilus && python-single-r1_pkg_setup
  62 }
  63
  64 src_unpack() {
  65         default
  66
  67         unpack "${S}"/clamtk.1.gz
  68
  69         use kde && unpack "${S}"/../clamtk-kde-${MY_PV_KDE}/clamtk-kde.1.gz
  70         use nautilus && unpack "${S}"/../clamtk-gnome-${MY_PV_NAUTILUS}/clamtk-gnome.1.gz
  71         use nemo && unpack "${S}"/../nemo-sendto-clamtk-${MY_PV_NEMO}/nemo-sendto-clamtk.1.gz
  72         use thunar && unpack "${S}"/../thunar-sendto-clamtk-${MY_PV_THUNAR}/thunar-sendto-clamtk.1.gz
  73 }
  74
  75 src_install() {
  76         dobin clamtk
  77
  78         perl_set_version
  79         insinto "${VENDOR_LIB}"/ClamTk
  80         doins lib/*.pm
  81
  82         use nls && domo po/*.mo
  83
  84         doicon images/clamtk.png images/clamtk.xpm
  85
  86         domenu clamtk.desktop
  87
  88         doman ../clamtk.1
  89
  90         if use kde; then
  91                 insinto /usr/share/kservices5/ServiceMenus
  92                 doins ../clamtk-kde-${MY_PV_KDE}/clamtk-kde.desktop
  93
  94                 doicon ../clamtk-kde-${MY_PV_KDE}/clamtk-kde.png ../clamtk-kde-${MY_PV_KDE}/clamtk-kde.xpm
  95
  96                 doman ../clamtk-kde.1
  97
  98                 docinto dolphin
  99                 dodoc ../clamtk-kde-${MY_PV_KDE}/CHANGES ../clamtk-kde-${MY_PV_KDE}/README.md
 100         fi
 101
 102         if use nautilus; then
 103                 insinto /usr/share/nautilus-python/extensions
 104                 doins ../clamtk-gnome-${MY_PV_NAUTILUS}/clamtk-gnome.py
 105
 106                 doicon ../clamtk-gnome-${MY_PV_NAUTILUS}/images/clamtk-gnome.png
 107
 108                 doman ../clamtk-gnome.1
 109
 110                 docinto nautilus
 111                 dodoc ../clamtk-gnome-${MY_PV_NAUTILUS}/CHANGES ../clamtk-gnome-${MY_PV_NAUTILUS}/DISCLAIMER ../clamtk-gnome-${MY_PV_NAUTILUS}/README.md
 112         fi
 113
 114         if use nemo; then
 115                 insinto /usr/share/nemo/actions/
 116                 doins ../nemo-sendto-clamtk-${MY_PV_NEMO}/nemo-sendto-clamtk.nemo_action
 117
 118                 doman ../nemo-sendto-clamtk.1
 119
 120                 docinto nemo
 121                 dodoc ../nemo-sendto-clamtk-${MY_PV_NEMO}/CHANGES ../nemo-sendto-clamtk-${MY_PV_NEMO}/DISCLAIMER ../nemo-sendto-clamtk-${MY_PV_NEMO}/README.md
 122         fi
 123
 124         if use thunar; then
 125                 insinto /usr/share/Thunar/sendto
 126                 doins ../thunar-sendto-clamtk-${MY_PV_THUNAR}/thunar-sendto-clamtk.desktop
 127
 128                 doman ../thunar-sendto-clamtk.1
 129
 130                 docinto thunar
 131                 dodoc ../thunar-sendto-clamtk-${MY_PV_THUNAR}/CHANGES ../thunar-sendto-clamtk-${MY_PV_THUNAR}/DISCLAIMER ../thunar-sendto-clamtk-${MY_PV_THUNAR}/README
 132         fi
 133
 134         einstalldocs
 135 }
 136
 137 pkg_postinst() {
 138         xdg_desktop_database_update
 139         xdg_mimeinfo_database_update
 140 }
 141
 142 pkg_postrm() {
 143         xdg_desktop_database_update
 144         xdg_mimeinfo_database_update
 145 }