app-admin/salt/salt-9999.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 inherit eutils systemd distutils-r1
   8
   9 DESCRIPTION="Salt is a remote execution and configuration manager"
  10 HOMEPAGE="http://saltstack.org/"
  11
  12 if [[ ${PV} == 9999* ]]; then
  13         inherit git-r3
  14         EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
  15         EGIT_BRANCH="develop"
  16         SRC_URI=""
  17         KEYWORDS=""
  18 else
  19         SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  20         KEYWORDS="~x86 ~amd64"
  21 fi
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="0"
  25 IUSE="cherrypy ldap libcloud libvirt gnupg keyring mako mongodb mysql neutron nova"
  26 IUSE+=" openssl portage profile redis selinux test timelib raet +zeromq vim-syntax"
  27
  28 RDEPEND="sys-apps/pciutils
  29         dev-python/jinja[${PYTHON_USEDEP}]
  30         >=dev-python/msgpack-0.3[${PYTHON_USEDEP}]
  31         dev-python/pyyaml[${PYTHON_USEDEP}]
  32         dev-python/markupsafe[${PYTHON_USEDEP}]
  33         >=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
  34         dev-python/setuptools[${PYTHON_USEDEP}]
  35         >=www-servers/tornado-4.2.1[${PYTHON_USEDEP}]
  36         virtual/python-futures[${PYTHON_USEDEP}]
  37         libcloud? ( >=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}] )
  38         mako? ( dev-python/mako[${PYTHON_USEDEP}] )
  39         ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
  40
  41         libvirt? ( dev-python/libvirt-python[${PYTHON_USEDEP}] )
  42         openssl? (
  43                 dev-libs/openssl:*[-bindist]
  44                 dev-python/pyopenssl[${PYTHON_USEDEP}]
  45         )
  46         raet? (
  47                 >=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
  48                 >=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
  49                 >=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
  50         )
  51         zeromq? (
  52                 >=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
  53                 >=dev-python/pycrypto-2.6.1[${PYTHON_USEDEP}]
  54         )
  55         cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
  56         mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
  57         portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
  58         keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
  59         mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
  60         redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
  61         selinux? ( sec-policy/selinux-salt )
  62         timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )
  63         nova? ( >=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}] )
  64         neutron? ( >=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}] )
  65         gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
  66         profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
  67         vim-syntax? ( app-vim/salt-vim )"
  68 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
  69         test? (
  70                 dev-python/psutil[${PYTHON_USEDEP}]
  71                 dev-python/pip[${PYTHON_USEDEP}]
  72                 dev-python/virtualenv[${PYTHON_USEDEP}]
  73                 dev-python/mock[${PYTHON_USEDEP}]
  74                 dev-python/timelib[${PYTHON_USEDEP}]
  75                 >=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
  76                 !x86? ( dev-python/boto3[${PYTHON_USEDEP}] )
  77                 >=dev-python/moto-0.3.6[${PYTHON_USEDEP}]
  78                 >=dev-python/SaltTesting-2016.5.11[${PYTHON_USEDEP}]
  79                 >=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}]
  80                 ${RDEPEND}
  81         )"
  82
  83 DOCS=( README.rst AUTHORS )
  84
  85 REQUIRED_USE="|| ( raet zeromq )"
  86 RESTRICT="x86? ( test )"
  87
  88 python_prepare() {
  89         # this test fails because it trys to "pip install distribute"
  90         rm tests/unit/{modules,states}/zcbuildout_test.py \
  91                 tests/unit/modules/{rh_ip,win_network}_test.py || die
  92
  93         # apparently libcloud does not know about this?
  94         rm tests/unit/cloud/clouds/dimensiondata_test.py || die
  95
  96         # seriously? "ValueError: Missing (or not readable) key file: '/home/dany/PRIVKEY.pem'"
  97         rm tests/unit/cloud/clouds/gce_test.py || die
  98 }
  99
 100 python_install_all() {
 101         local svc
 102         USE_SETUPTOOLS=1 distutils-r1_python_install_all
 103
 104         for svc in minion master syndic api; do
 105                 newinitd "${FILESDIR}"/${svc}-initd-4 salt-${svc}
 106                 newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
 107                 systemd_dounit "${FILESDIR}"/salt-${svc}.service
 108         done
 109
 110         insinto /etc/${PN}
 111         doins -r conf/*
 112 }
 113
 114 python_test() {
 115         local tempdir
 116         # testsuite likes lots of files
 117         ulimit -n 3072 || die
 118
 119         # ${T} is too long a path for the tests to work
 120         tempdir="$(mktemp -dup /tmp salt-XXX)"
 121         mkdir "${T}/$(basename "${tempdir}")"
 122
 123         (
 124                 cleanup() { rm -f "${tempdir}"; }
 125                 trap cleanup EXIT
 126
 127                 addwrite "${tempdir}"
 128                 ln -s "$(realpath --relative-to=/tmp "${T}/$(basename "${tempdir}")")" "${tempdir}"
 129
 130                 USE_SETUPTOOLS=1 SHELL="/bin/bash" \
 131                         TMPDIR="${tempdir}" \
 132                         ${EPYTHON} tests/runtests.py \
 133                         --unit-tests --no-report --verbose
 134
 135         ) || die "testing failed"
 136 }